[arch-commits] Commit in i3lock/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 7, 2020 @ 18:07:23
  Author: felixonmars
Revision: 659996

archrelease: copy trunk to community-staging-x86_64

Added:
  i3lock/repos/community-staging-x86_64/
  i3lock/repos/community-staging-x86_64/PKGBUILD
    (from rev 659995, i3lock/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: i3lock/repos/community-staging-x86_64/PKGBUILD (from rev 659995, i3lock/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-07 18:07:23 UTC (rev 659996)
@@ -0,0 +1,49 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributor: Thorsten Töpper <atsutane-tu at freethoughts.de>
+
+pkgname=i3lock
+pkgver=2.12
+pkgrel=2
+pkgdesc='Improved screenlocker based upon XCB and PAM'
+url='https://i3wm.org/i3lock/'
+arch=('x86_64')
+license=('MIT')
+groups=('i3')
+depends=('xcb-util-image' 'xcb-util-xrm' 'libev' 'cairo' 'libxkbcommon-x11' 'pam')
+options=('docs')
+backup=('etc/pam.d/i3lock')
+source=(https://i3wm.org/i3lock/$pkgname-$pkgver.tar.bz2{,.asc}
+        gcc10.patch::https://github.com/i3/i3lock/commit/3daf34bb03841f8e201ceb14b7124945d4c18bb8.patch)
+sha512sums=('84f1558368381bcad9a64f41ab6134a6614dea453d1ee5ecfe886185b9e1baebeeca446c4635158deb8dae5b25c09d47d3990239d76c44e5325ca5bfaad9b2ad'
+            'SKIP'
+            '0e690688f827491080d44004b07ecd66a3d2930db1496fe7411af504a1aa6ca3c354a43359c575579ed6007c586afc6a4e48c051090ef2ee4af32a003c91d8c7')
+validpgpkeys=('424E14D703E7C6D43D9D6F364E7160ED4AC8EE1D') # Michael Stapelberg
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+
+  patch -Np1 -i ${srcdir}/gcc10.patch
+
+  # Fix ticket FS#31544, sed line taken from gentoo
+  sed -i -e 's:login:system-auth:' pam/i3lock
+  autoreconf -fiv
+}
+
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 i3lock.1 -t "${pkgdir}/usr/share/man/man1"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: