[arch-commits] Commit in kde-dev-scripts/repos (staging-any staging-any/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, July 9, 2020 @ 13:50:49
  Author: arojas
Revision: 391228

archrelease: copy trunk to staging-any

Added:
  kde-dev-scripts/repos/staging-any/
  kde-dev-scripts/repos/staging-any/PKGBUILD
    (from rev 391227, kde-dev-scripts/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: kde-dev-scripts/repos/staging-any/PKGBUILD (from rev 391227, kde-dev-scripts/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2020-07-09 13:50:49 UTC (rev 391228)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kde-dev-scripts
+pkgver=20.04.3
+pkgrel=1
+pkgdesc='Scripts and setting files useful during development of KDE software'
+url='https://www.kde.org/applications/development/'
+arch=(any)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdesdk)
+depends=(perl)
+makedepends=(extra-cmake-modules kdoctools)
+source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('0b321954ea79e829d81c9be0170babae87e5eab22c8d42b296746d5a0160fbae'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  # Fix python 2 path
+  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{zonetab2pot.py,kde-systemsettings-tree.py,reviewboard-am}
+  sed -i 's|#! /usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{kdelnk2desktop.py,kde_generate_export_header}
+
+# Install additional files
+  cd "$srcdir"/$pkgname-$pkgver
+  mkdir -p "$pkgdir"/usr/share/kde-dev-scripts
+  cp -r kde-devel-* gdb "$pkgdir"/usr/share/kde-dev-scripts
+}