[arch-commits] Commit in python-authlib/repos (community-any community-any/PKGBUILD)

Eli Schwartz eschwartz at archlinux.org
Fri Jul 10 14:38:17 UTC 2020


    Date: Friday, July 10, 2020 @ 14:38:15
  Author: eschwartz
Revision: 663110

archrelease: copy trunk to community-any

Added:
  python-authlib/repos/community-any/
  python-authlib/repos/community-any/PKGBUILD
    (from rev 663109, python-authlib/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-authlib/repos/community-any/PKGBUILD (from rev 663109, python-authlib/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2020-07-10 14:38:15 UTC (rev 663110)
@@ -0,0 +1,50 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=authlib
+pkgname=python-authlib
+pkgver=0.14.3
+_commit=ffdc4378a2b0c8e6627170396384d1bfcfb7ed40
+pkgrel=2
+pkgdesc="The ultimate Python library in building OAuth and OpenID Connect servers"
+arch=('any')
+url="https://github.com/lepture/${_pkgname}"
+license=('BSD')
+depends=('python-cryptography')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest-asyncio' 'python-pytest-django' 'python-requests'
+              'python-django' 'python-flask-sqlalchemy' 'python-httpx' 'python-starlette')
+source=("git+${url}.git#commit=${_commit}?signed")
+b2sums=('SKIP')
+validpgpkeys=('72F8E895A70CEBDF4F2ADFE07E55E3E0118B2B4C') # Hsiaoming (UJET) <lepture at ujet.co>
+
+pkgver() {
+    cd "${srcdir}"/${_pkgname}
+
+    git describe --exact-match --tags | sed 's/^v//'
+}
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}
+
+    # no need to install an additional copy of the stdlib
+    find tests -name \*.py -exec sed -i 's/^import mock$/from unittest import mock/' {} +
+}
+
+build() {
+    cd "${srcdir}"/${_pkgname}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}
+
+    python -m pytest
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}


More information about the arch-commits mailing list