[arch-commits] Commit in keepassxc/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Balló György]

    Date: Friday, July 10, 2020 @ 21:59:52
  Author: bgyorgy
Revision: 663227

archrelease: copy trunk to community-x86_64

Added:
  keepassxc/repos/community-x86_64/PKGBUILD
    (from rev 663226, keepassxc/trunk/PKGBUILD)
Deleted:
  keepassxc/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   81 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 41 insertions(+), 40 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-07-10 21:59:49 UTC (rev 663226)
+++ PKGBUILD	2020-07-10 21:59:52 UTC (rev 663227)
@@ -1,40 +0,0 @@
-# Maintainer: Balló György <ballogyor+arch at gmail dot com>
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-
-pkgname=keepassxc
-pkgver=2.5.4
-pkgrel=2
-pkgdesc="Cross-platform community-driven port of Keepass password manager"
-arch=(x86_64)
-url="https://keepassxc.org/"
-license=(GPL)
-depends=(argon2 curl libgcrypt libsodium libxtst qrencode
-         qt5-svg qt5-x11extras quazip yubikey-personalization)
-makedepends=(cmake qt5-tools)
-optdepends=('xclip: keepassxc-cli clipboard support')
-provides=(org.freedesktop.secrets)
-source=(https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/keepassxc-$pkgver-src.tar.xz{,.sig})
-sha256sums=('a55e0801c318b02b1ac4e16e9b7a87ccfa7b039ea60d2c62610bd1bbbdd6cd4a' 'SKIP')
-# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
-validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
-              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
-              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
-              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)
-
-build() {
-    cmake -S keepassxc-$pkgver -B build \
-        -DCMAKE_BUILD_TYPE=Release \
-        -DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_INSTALL_LIBDIR=lib \
-        -DWITH_XC_ALL=ON \
-        -DWITH_XC_UPDATECHECK=OFF
-    cmake --build build
-}
-
-check() {
-    cmake --build build --target test
-}
-
-package() {
-    cmake --build build --target install -- DESTDIR="$pkgdir"
-}

Copied: keepassxc/repos/community-x86_64/PKGBUILD (from rev 663226, keepassxc/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-07-10 21:59:52 UTC (rev 663227)
@@ -0,0 +1,41 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=keepassxc
+pkgver=2.6.0
+pkgrel=1
+pkgdesc="Cross-platform community-driven port of Keepass password manager"
+arch=(x86_64)
+url="https://keepassxc.org/"
+license=(GPL)
+depends=(argon2 curl hicolor-icon-theme libgcrypt libsodium libxtst qrencode
+         qt5-svg qt5-x11extras quazip yubikey-personalization)
+makedepends=(asciidoctor cmake qt5-tools)
+optdepends=('xclip: keepassxc-cli clipboard support')
+provides=(org.freedesktop.secrets)
+source=(https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/keepassxc-$pkgver-src.tar.xz{,.sig})
+sha256sums=('d0d23d97a73ac1cbf59bfca2f5d1506ae36dfcd4fbfb4225efe19931f035fd3a'
+            'SKIP')
+# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
+validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
+              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
+              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
+              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)
+
+build() {
+    cmake -S keepassxc-$pkgver -B build \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DWITH_XC_ALL=ON \
+        -DWITH_XC_UPDATECHECK=OFF
+    cmake --build build
+}
+
+check() {
+    cmake --build build --target test
+}
+
+package() {
+    cmake --build build --target install -- DESTDIR="$pkgdir"
+}