[arch-commits] Commit in kconfigwidgets/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, July 11, 2020 @ 06:45:32
  Author: arojas
Revision: 391570

archrelease: copy trunk to staging-x86_64

Added:
  kconfigwidgets/repos/staging-x86_64/
  kconfigwidgets/repos/staging-x86_64/PKGBUILD
    (from rev 391569, kconfigwidgets/trunk/PKGBUILD)

----------+
 PKGBUILD |   30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)

Copied: kconfigwidgets/repos/staging-x86_64/PKGBUILD (from rev 391569, kconfigwidgets/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-07-11 06:45:32 UTC (rev 391570)
@@ -0,0 +1,30 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kconfigwidgets
+pkgver=5.72.0
+pkgrel=1
+pkgdesc='Widgets for KConfig'
+arch=(x86_64)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(kauth kcodecs kconfig kguiaddons ki18n kwidgetsaddons)
+makedepends=(extra-cmake-modules kdoctools clang python-pyqt5 doxygen qt5-tools qt5-doc sip)
+optdepends=('python-pyqt5: for the Python bindings' 'perl: for preparetips5')
+groups=(kf5)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('1ccbb1d87b403e75e9ee9980eb27c2e24aab26f99b1335e415226f1cb7f6f61d'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}