[arch-commits] Commit in haskell-persistent-template/repos (2 files)

[Felix Yan]

    Date: Wednesday, July 15, 2020 @ 09:26:07
  Author: felixonmars
Revision: 663896

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-template/repos/community-staging-x86_64/
  haskell-persistent-template/repos/community-staging-x86_64/PKGBUILD
    (from rev 663895, haskell-persistent-template/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-persistent-template/repos/community-staging-x86_64/PKGBUILD (from rev 663895, haskell-persistent-template/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-15 09:26:07 UTC (rev 663896)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent-template
+pkgname=haskell-persistent-template
+pkgver=2.8.2.3
+pkgrel=61
+pkgdesc="Type-safe, non-relational, multi-backend persistence"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-aeson" "haskell-http-api-data" "haskell-monad-control"
+         "haskell-monad-logger" "haskell-path-pieces" "haskell-persistent"
+         'haskell-th-lift-instances' "haskell-unordered-containers")
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('eef94f07783f2b61ed4d00c75a57e976e2546ee1cb564471ea33e5faf01634701a7b60b4c1ee64594e0058949966f132fe46f1a5efc5a64f949fc6e6b27d5ddb')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *1.5/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}