[arch-commits] Commit in jami-daemon/repos (2 files)

[Antonio Rojas]

    Date: Thursday, July 16, 2020 @ 07:08:21
  Author: arojas
Revision: 664103

archrelease: copy trunk to community-staging-x86_64

Added:
  jami-daemon/repos/community-staging-x86_64/
  jami-daemon/repos/community-staging-x86_64/PKGBUILD
    (from rev 664102, jami-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: jami-daemon/repos/community-staging-x86_64/PKGBUILD (from rev 664102, jami-daemon/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-07-16 07:08:21 UTC (rev 664103)
@@ -0,0 +1,67 @@
+# Maintainer: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkgname=ring-daemon
+pkgname=jami-daemon
+pkgver=20190813
+pkgrel=5
+_pjprojectver=5dfa75be7d69047387f9b0436dd9492bbbf03fe4
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(opendht yaml-cpp alsa-lib libpulse jack jsoncpp dbus-c++ ffmpeg gnutls
+         expat libupnp libnatpmp libva libvdpau restbed libsecp256k1 util-linux
+         opus libjsoncpp.so)
+makedepends=(git boost msgpack-c autoconf-archive)
+#checkdepends=(cppunit)
+provides=(${_pkgname})
+conflicts=(${_pkgname})
+replaces=(${_pkgname})
+_commit=26b35255a94aa9a13cbf3b3aa530d4b282a79565
+source=("git+https://git.jami.net/savoirfairelinux/ring-daemon.git#commit=${_commit}"
+        "https://github.com/pjsip/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz")
+noextract=("pjproject-${_pjprojectver}.tar.gz")
+sha512sums=('SKIP'
+            'a9433b47294434288d61524dea556687fb02137ed56a10e8e2ba85d7888a2ca2a5bea4ae4a9ad008a4c208c5ec53fe364b10ed14481700d6aa8b9b6137e5e9ee')
+
+prepare() {
+  cd ${_pkgname}
+
+  git cherry-pick -n 14deb3d34bde107744bf27e34de0608e7801f4d2 # Fix build with GCC 10
+
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+  autoreconf -fvi
+}
+
+build() {
+  cd ${_pkgname}/contrib/native
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd ../..
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib \
+    --sysconfdir=/etc \
+    --enable-ipv6
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+# Disabled because some tests (TURN) use the network.
+#check() {
+#  cd ${_pkgname}
+#  make -k check
+#}
+
+package() {
+  cd ${_pkgname}
+  make DESTDIR="${pkgdir}" install
+}