[arch-commits] Commit in akonadi/repos/kde-unstable-x86_64 (PKGBUILD)

Antonio Rojas arojas at archlinux.org
Fri Jul 17 23:14:31 UTC 2020


    Date: Friday, July 17, 2020 @ 23:14:31
  Author: arojas
Revision: 392070

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  akonadi/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 392069, akonadi/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: akonadi/repos/kde-unstable-x86_64/PKGBUILD (from rev 392069, akonadi/kde-unstable/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-07-17 23:14:31 UTC (rev 392070)
@@ -0,0 +1,41 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=akonadi
+pkgname=(akonadi libakonadi)
+pkgver=20.07.80
+pkgrel=1
+pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data"
+arch=(x86_64)
+url='https://kontact.kde.org'
+license=(LGPL)
+makedepends=(extra-cmake-modules postgresql qt5-tools boost kitemmodels kaccounts-integration)
+source=("https://download.kde.org/unstable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('df00efa7be88423658a56c8ebee5510e4ca3632524f460f47b064a66afa48ea3'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_libakonadi() {
+  pkgdesc='Libraries used by applications based on Akonadi'
+  depends=(kitemmodels kaccounts-integration)
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/bin # Provided by akonadi
+}
+
+package_akonadi() {
+  depends=(libakonadi mariadb)
+  optdepends=('postgresql: PostgreSQL backend')
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/{etc,usr/{include,lib,share}} # Provided by libakonadi
+}


More information about the arch-commits mailing list