[arch-commits] Commit in kate/repos (kde-unstable-x86_64 kde-unstable-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Friday, July 17, 2020 @ 23:37:12
  Author: arojas
Revision: 392239

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  kate/repos/kde-unstable-x86_64/
  kate/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 392238, kate/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: kate/repos/kde-unstable-x86_64/PKGBUILD (from rev 392238, kate/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2020-07-17 23:37:12 UTC (rev 392239)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=kate
+pkgname=(kwrite kate)
+pkgver=20.07.80
+pkgrel=1
+arch=(x86_64)
+license=(GPL LGPL FDL)
+makedepends=(extra-cmake-modules kdoctools plasma-framework knewstuff kitemmodels ktexteditor threadweaver kactivities kuserfeedback)
+source=("https://download.kde.org/unstable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('f62710582ab5b5768a1689d0d2933db71fd7a76cd45cede6f30a27348ed4e9e1'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_kwrite() {
+  pkgdesc="Text Editor"
+  groups=(kde-applications kde-utilities)
+  url="https://www.kde.org/applications/utilities/kwrite/"
+  depends=(ktexteditor hicolor-icon-theme)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
+        "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
+        "$pkgdir"/usr/share/katexmltools \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{ktexteditorpreviewplugin,lspclient,tabswitcherplugin}.mo \
+        "$pkgdir"/usr/share/plasma/plasmoids
+}
+
+package_kate() {
+  pkgdesc="Advanced Text Editor"
+  groups=(kde-applications kde-utilities)
+  url="https://www.kde.org/applications/utilities/kate/"
+  depends=(knewstuff ktexteditor threadweaver kactivities kuserfeedback hicolor-icon-theme)
+  optdepends=('konsole: open a terminal in Kate'
+              'clang: C and C++ LSP support'
+              'python-language-server: Python LSP support'
+              'texlab: LaTeX LSP support'
+              'rust: Rust LSP support')
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
+}