[arch-commits] Commit in tbb/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Sun Jul 19 15:33:17 UTC 2020


    Date: Sunday, July 19, 2020 @ 15:33:17
  Author: felixonmars
Revision: 392288

archrelease: copy trunk to testing-x86_64

Added:
  tbb/repos/testing-x86_64/
  tbb/repos/testing-x86_64/PKGBUILD
    (from rev 392287, tbb/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: tbb/repos/testing-x86_64/PKGBUILD (from rev 392287, tbb/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-07-19 15:33:17 UTC (rev 392288)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Denis Martinez <deuns.martinez AT gmail.com>
+# Contributor: Bogdan Burlacu <bogdan.burlacu AT pm.me>
+
+pkgname=tbb
+pkgver=2020.3
+pkgrel=1
+pkgdesc='High level abstract threading library'
+arch=('x86_64')
+url='https://www.threadingbuildingblocks.org/'
+license=('Apache')
+depends=('gcc-libs')
+makedepends=('cmake' 'inetutils')
+conflicts=('intel-tbb')
+provides=("intel-tbb=$pkgver")
+replaces=('intel-tbb')
+source=(https://github.com/oneapi-src/oneTBB/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
+sha512sums=('ea1ffd22c7234d715b8c46a4e51b40719c7a9b8837ab3166f1da5a2c6061167c2be2126b1d74fd361eec6975b8fce0df26829ca2e7af8029edbb52e40f23d630')
+
+build() {
+  cd oneTBB-$pkgver
+  make
+}
+
+package() {
+  cd oneTBB-$pkgver
+  install -Dm755 build/linux_*/*.so* -t "$pkgdir"/usr/lib
+  install -d "$pkgdir"/usr/include
+  cp -a include/tbb "$pkgdir"/usr/include
+  cmake \
+    -DINSTALL_DIR="$pkgdir"/usr/lib/cmake/TBB \
+    -DSYSTEM_NAME=Linux -DTBB_VERSION_FILE="$pkgdir"/usr/include/tbb/tbb_stddef.h \
+    -P cmake/tbb_config_installer.cmake
+}


More information about the arch-commits mailing list