[arch-commits] Commit in kdevelop/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Evangelos Foutras foutrelis at archlinux.org
Wed Jul 22 21:29:16 UTC 2020


    Date: Wednesday, July 22, 2020 @ 21:29:16
  Author: foutrelis
Revision: 392395

archrelease: copy trunk to staging-x86_64

Added:
  kdevelop/repos/staging-x86_64/
  kdevelop/repos/staging-x86_64/PKGBUILD
    (from rev 392394, kdevelop/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: kdevelop/repos/staging-x86_64/PKGBUILD (from rev 392394, kdevelop/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-07-22 21:29:16 UTC (rev 392395)
@@ -0,0 +1,47 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+
+pkgname=kdevelop
+pkgver=5.5.2
+_clangver=10.0.1
+pkgrel=3
+pkgdesc='C++ IDE using KDE technologies'
+arch=(x86_64)
+url='http://www.kdevelop.org/'
+license=(GPL)
+depends=(clang=$_clangver libksysguard kitemmodels knotifyconfig ktexteditor grantlee libkomparediff2
+         kcmutils threadweaver knewstuff)
+makedepends=(extra-cmake-modules kdoctools kdevelop-pg-qt llvm qt5-tools plasma-framework krunner okteta boost purpose subversion astyle)
+optdepends=('konsole: embedded terminal'
+            'git: Git support' 'subversion: SVN support'
+            'gdb: GNU debugger support' 'lldb: LLDB debugger support'
+            'qt5-doc: Qt documentation integration'
+            'cmake: cmake integration'
+            'meson: meson integration'
+            'qt5-tools: qthelp plugin'
+            'okteta: GNU debugger support'
+            'plasma-framework: for the plasma addons'
+            'purpose: patch review plugin'
+            'astyle: astyle plugin'
+            'cppcheck: code analyzer' 'heaptrack: memory profiler'
+            'clazy: clazy analyzer plugin')
+conflicts=(kdevelop-qmljs kdevplatform)
+replaces=(kdevelop-qmljs kdevplatform kdevelop-clang-tidy)
+source=("https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('228e981a268704fef0f8fa437e37e3e2e0d261d3a2afbabff0f4d060c31f74da'
+            'SKIP')
+validpgpkeys=('329FD02C5AA48FCC77A4BBF0AC44AC6DB29779E6'  # Sven Brauch <mail at svenbrauch.de>
+              '364EFA5F639572907D392999C64CF56B13CACE5D'  # Kevin Funk <kfunk at kde.org>
+              'E191FD5BE6F46870F09E82B2024E7FB43D015474'  # Friedrich W. H. Kossebau <kossebau at kde.org>
+              '0A48BC961075B4BA8523E3790A345FB086E797D9') # https://share.kde.org/s/8dKaJTw8pR8iiwJ
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}


More information about the arch-commits mailing list