[arch-commits] Commit in opencv/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, July 25, 2020 @ 06:53:37
  Author: arojas
Revision: 392521

archrelease: copy trunk to staging-x86_64

Added:
  opencv/repos/staging-x86_64/
  opencv/repos/staging-x86_64/PKGBUILD
    (from rev 392520, opencv/trunk/PKGBUILD)

----------+
 PKGBUILD |   79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

Copied: opencv/repos/staging-x86_64/PKGBUILD (from rev 392520, opencv/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-07-25 06:53:37 UTC (rev 392521)
@@ -0,0 +1,79 @@
+# Maintainer: Ray Rashif <schiv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgbase=opencv
+pkgname=(opencv opencv-samples)
+pkgver=4.4.0
+pkgrel=1
+pkgdesc="Open Source Computer Vision Library"
+arch=(x86_64)
+license=(BSD)
+url="https://opencv.org/"
+depends=(tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 openjpeg2 ffmpeg)
+makedepends=(cmake python-numpy python-setuptools mesa eigen hdf5 lapacke qt5-base vtk glew ant java-environment)
+optdepends=('opencv-samples: samples'
+            'vtk: for the viz module'
+            'qt5-base: for the HighGUI module and the Python bindings'
+            'hdf5: for the HDF5 module and the Python bindings'
+            'opencl-icd-loader: For coding with OpenCL'
+            'python-numpy: Python bindings'
+            'java-runtime: Java interface')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/opencv/opencv/archive/$pkgver.zip"
+        "opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz")
+sha256sums=('7faa0991c74cda52313ee37ef73f3e451332a47e7aa36c2bb2240b69f5002d27'
+            'a69772f553b32427e09ffbfd0c8d5e5e47f7dab8b3ffc02851ffd7f912b76840')
+
+build() {
+  export JAVA_HOME="/usr/lib/jvm/default"
+  # cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  cmake -B build -S $pkgname-$pkgver \
+    -DWITH_OPENCL=ON \
+    -DWITH_OPENGL=ON \
+    -DWITH_TBB=ON \
+    -DWITH_VULKAN=ON \
+    -DWITH_QT=ON \
+    -DBUILD_WITH_DEBUG_INFO=OFF \
+    -DBUILD_TESTS=OFF \
+    -DBUILD_PERF_TESTS=OFF \
+    -DBUILD_EXAMPLES=ON \
+    -DINSTALL_C_EXAMPLES=ON \
+    -DINSTALL_PYTHON_EXAMPLES=ON \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCPU_BASELINE_DISABLE=SSE3 \
+    -DCPU_BASELINE_REQUIRE=SSE2 \
+    -DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
+    -DOPENCV_SKIP_PYTHON_LOADER=ON \
+    -DOPENCV_PYTHON3_INSTALL_PATH=$_pythonpath \
+    -DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
+    -DLAPACK_CBLAS_H="/usr/include/cblas.h" \
+    -DLAPACK_LAPACKE_H="/usr/include/lapacke.h" \
+    -DOPENCV_GENERATE_PKGCONFIG=ON \
+    -DOPENCV_ENABLE_NONFREE=ON \
+    -DOPENCV_JNI_INSTALL_PATH=lib \
+    -DOPENCV_GENERATE_SETUPVARS=OFF \
+    -DEIGEN_INCLUDE_PATH=/usr/include/eigen3
+  cmake --build build
+}
+
+package_opencv() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  # install license file
+  install -Dm644 $pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+
+  # separate samples package
+  mv "$pkgdir"/usr/share/opencv4/samples "$srcdir"
+}
+
+package_opencv-samples() {
+  pkgdesc+=" (samples)"
+  depends=("opencv=$pkgver")
+  unset optdepends
+
+  mkdir -p "$pkgdir"/usr/share/opencv4
+  mv samples "$pkgdir"/usr/share/opencv4
+
+  # install license file
+  install -Dm644 opencv-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}