[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Tuesday, July 28, 2020 @ 00:09:55
  Author: archange
Revision: 665565

Initial addition of python-partd, required by dask

Added:
  python-partd/
  python-partd/repos/
  python-partd/trunk/
  python-partd/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-partd/trunk/PKGBUILD
===================================================================
--- python-partd/trunk/PKGBUILD	                        (rev 0)
+++ python-partd/trunk/PKGBUILD	2020-07-28 00:09:55 UTC (rev 665565)
@@ -0,0 +1,48 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=partd
+pkgname=python-${_pkg}
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Concurrent appendable key-value storage"
+arch=(any)
+url="https://github.com/dask/partd"
+license=(BSD)
+makedepends=(python-setuptools)
+depends=(
+    python
+    python-locket
+    python-toolz
+)
+optdepends=(
+    python-blosc
+    python-numpy
+    python-pandas
+    python-pyzmq
+)
+checkdepends=(
+    python-pytest
+    python-blosc
+    python-numpy
+    python-pandas
+    python-pyzmq
+)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('6e258bf0810701407ad1410d63d1a15cfd7b773fd9efe555dac6bb82cc8832b0')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  PYTHONPATH="${PWD}"/build/lib pytest
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+  # Install license file
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}