[arch-commits] Commit in kmon/repos (community-x86_64 community-x86_64/PKGBUILD)

Eli Schwartz eschwartz at archlinux.org
Wed Jul 29 23:38:36 UTC 2020


    Date: Wednesday, July 29, 2020 @ 23:38:36
  Author: eschwartz
Revision: 665857

archrelease: copy trunk to community-x86_64

Added:
  kmon/repos/community-x86_64/
  kmon/repos/community-x86_64/PKGBUILD
    (from rev 665856, kmon/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: kmon/repos/community-x86_64/PKGBUILD (from rev 665856, kmon/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-07-29 23:38:36 UTC (rev 665857)
@@ -0,0 +1,35 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: orhun <orhunparmaksiz at gmail.com>
+
+pkgname=kmon
+pkgver=1.3.4
+pkgrel=2
+pkgdesc="Linux kernel manager and activity monitor"
+arch=('x86_64')
+url="https://github.com/orhun/kmon"
+license=('GPL3')
+depends=('kmod' 'libxcb')
+makedepends=('cargo' 'python' 'git')
+source=("git+${url}.git#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('39E678DF63BE20EA5A175156B928720AEC532117') # orhun <orhunparmaksiz at gmail.com>
+
+build() {
+    cd "${srcdir}"/${pkgname}
+
+    cargo build --release --locked --all-features
+}
+
+check() {
+    cd "${srcdir}"/${pkgname}
+
+    cargo test --release --locked
+}
+
+package() {
+    cd "${srcdir}"/${pkgname}
+
+    install -Dm755 target/release/${pkgname} -t "${pkgdir}"/usr/bin
+    install -Dm644 README.md -t "${pkgdir}"/usr/share/doc/${pkgname}
+    install -Dm644 man/${pkgname}.8 -t "${pkgdir}"/usr/share/man/man8
+}


More information about the arch-commits mailing list