[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, July 30, 2020 @ 17:52:39
  Author: felixonmars
Revision: 665930

addpkg: haskell-libbf 0.5.1-1 (for new cryptol)

Added:
  haskell-libbf/
  haskell-libbf/repos/
  haskell-libbf/trunk/
  haskell-libbf/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-libbf/trunk/PKGBUILD
===================================================================
--- haskell-libbf/trunk/PKGBUILD	                        (rev 0)
+++ haskell-libbf/trunk/PKGBUILD	2020-07-30 17:52:39 UTC (rev 665930)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=libBF
+pkgname=haskell-libbf
+pkgver=0.5.1
+pkgrel=1
+pkgdesc="A binding to the libBF library"
+url="https://github.com/GaloisInc/libBF-hs"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'libbf')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('8d8f9b5b5fd15558660c3799431b5413bf0bf79e7e115aa69fdda2356360c0a16c2b6a3674b6b28bfe47b1a6a0bcbbe92fea9c7836ee5916e5d10084ee03a1a0')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/libbf-2020/d;/include/d;/c-sources:/i \  extra-libraries: bf' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}