[arch-commits] Commit in nodejs/repos (3 files)

[Felix Yan]

    Date: Wednesday, June 3, 2020 @ 08:01:16
  Author: felixonmars
Revision: 638201

archrelease: copy trunk to community-testing-x86_64

Added:
  nodejs/repos/community-testing-x86_64/
  nodejs/repos/community-testing-x86_64/PKGBUILD
    (from rev 638200, nodejs/trunk/PKGBUILD)
  nodejs/repos/community-testing-x86_64/rebuild.list
    (from rev 638200, nodejs/trunk/rebuild.list)

--------------+
 PKGBUILD     |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 rebuild.list |    2 ++
 2 files changed, 59 insertions(+)

Copied: nodejs/repos/community-testing-x86_64/PKGBUILD (from rev 638200, nodejs/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-06-03 08:01:16 UTC (rev 638201)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor  Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: James Campos <james.r.campos at gmail.com>
+# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
+# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
+# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
+# Contributor: TIanyi Cui <tianyicui at gmail.com>
+
+pkgname=nodejs
+pkgver=14.4.0
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript'
+arch=('x86_64')
+url='https://nodejs.org/'
+license=('MIT')
+depends=('openssl' 'zlib' 'icu' 'libuv' 'c-ares' 'libnghttp2') # 'http-parser' 'v8')
+makedepends=('python' 'procps-ng')
+optdepends=('npm: nodejs package manager')
+source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz")
+sha512sums=('88e8acc9b3359a57f0ed8d4d6e5af1d8d3595360348b76a52b12647d95bfb9668cc7587218cdc9e969cbcdc7a10ec3f5082b23787d1d61bf5e0cb4b94c40d290')
+
+build() {
+  cd node-$pkgver
+
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --experimental-http-parser \
+    --shared-cares \
+    --shared-nghttp2
+    # --shared-v8
+    # --shared-http-parser
+
+  make
+}
+
+check() {
+  cd node-$pkgver
+  # Expected failure: https://github.com/nodejs/node/issues/11627
+  make test || warning "Tests failed"
+}
+
+package() {
+  cd node-$pkgver
+
+  make DESTDIR="$pkgdir" install
+
+  install -D -m644 LICENSE \
+    "$pkgdir"/usr/share/licenses/nodejs/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Copied: nodejs/repos/community-testing-x86_64/rebuild.list (from rev 638200, nodejs/trunk/rebuild.list)
===================================================================
--- community-testing-x86_64/rebuild.list	                        (rev 0)
+++ community-testing-x86_64/rebuild.list	2020-06-03 08:01:16 UTC (rev 638201)
@@ -0,0 +1,2 @@
+apm
+bash-language-server