[arch-commits] Commit in links/repos (3 files)

Christian Hesse eworm at archlinux.org
Thu Jun 4 11:44:10 UTC 2020


    Date: Thursday, June 4, 2020 @ 11:44:09
  Author: eworm
Revision: 388274

archrelease: copy trunk to testing-x86_64

Added:
  links/repos/testing-x86_64/
  links/repos/testing-x86_64/PKGBUILD
    (from rev 388273, links/trunk/PKGBUILD)
  links/repos/testing-x86_64/links.desktop
    (from rev 388273, links/trunk/links.desktop)

---------------+
 PKGBUILD      |   65 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 links.desktop |    8 ++++++
 2 files changed, 73 insertions(+)

Copied: links/repos/testing-x86_64/PKGBUILD (from rev 388273, links/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-06-04 11:44:09 UTC (rev 388274)
@@ -0,0 +1,65 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=links
+pkgver=2.20.2
+pkgrel=4
+pkgdesc="A text WWW browser, similar to Lynx"
+arch=('x86_64')
+url="http://links.twibright.com/"
+license=('GPL')
+depends=('bzip2' 'gpm' 'libevent' 'pcre' 'xz')
+makedepends=('libtiff' 'libpng' 'libxt' 'librsvg')
+optdepends=('libx11: for using xlinks'
+	    'libtiff: for using xlinks'
+	    'libpng: for using xlinks'
+	    'librsvg: for using xlinks')
+source=("http://links.twibright.com/download/${pkgname}-${pkgver}.tar.bz2"
+        'links.desktop')
+sha256sums=('4b4f07d0e6261118d1365a5a5bfa31e1eafdbd280cfae6f0e9eedfea51a2f424'
+            'f96bf2638e9c309bfdb857bd62a732b980231b3a683cd585ec872b249c2c1b19')
+
+configure_options=(
+  --prefix=/usr
+  --mandir=/usr/share/man
+  --disable-javascript
+)
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" configure
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  (cd intl; ./gen-intl; ./synclang)
+  ./configure \
+    "${configure_options[@]}" \
+    --enable-graphics \
+    --with-x \
+    --with-fb
+  make
+  mv links xlinks
+
+  ./configure \
+    "${configure_options[@]}" \
+    --disable-graphics \
+    --without-x \
+    --without-fb
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+
+  install -D -m0755 xlinks "${pkgdir}/usr/bin/xlinks"
+  ln -s links.1.gz "${pkgdir}/usr/share/man/man1/xlinks.1.gz"
+
+  install -D -m0644 "${srcdir}/links.desktop" "${pkgdir}/usr/share/applications/links.desktop"
+  install -d "${pkgdir}/usr/share/pixmaps"
+  install -m0644 links_16x16_1.xpm links_16x16_2.xpm links_32x32.xpm links-48x48.xpm "${pkgdir}/usr/share/pixmaps/"
+
+  install -d "${pkgdir}/usr/share/doc/links/calibration"
+  install -m0644 doc/links_cal/* "${pkgdir}/usr/share/doc/links/calibration/"
+}

Copied: links/repos/testing-x86_64/links.desktop (from rev 388273, links/trunk/links.desktop)
===================================================================
--- testing-x86_64/links.desktop	                        (rev 0)
+++ testing-x86_64/links.desktop	2020-06-04 11:44:09 UTC (rev 388274)
@@ -0,0 +1,8 @@
+[Desktop Entry]
+Name=Links
+Comment=Minimal web browser in graphical mode
+Exec=xlinks -g
+Icon=links-48x48.xpm
+Type=Application
+Terminal=false
+Categories=Network;WebBrowser;


More information about the arch-commits mailing list