[arch-commits] Commit in avidemux/repos (4 files)
Jan Steffens
heftig at archlinux.org
Fri Jun 5 13:58:39 UTC 2020
Date: Friday, June 5, 2020 @ 13:58:39
Author: heftig
Revision: 388341
archrelease: copy trunk to staging-x86_64
Added:
avidemux/repos/staging-x86_64/
avidemux/repos/staging-x86_64/PKGBUILD
(from rev 388340, avidemux/trunk/PKGBUILD)
avidemux/repos/staging-x86_64/log.diff
(from rev 388340, avidemux/trunk/log.diff)
avidemux/repos/staging-x86_64/qt-5.15.diff
(from rev 388340, avidemux/trunk/qt-5.15.diff)
--------------+
PKGBUILD | 80 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
log.diff | 12 ++++++++
qt-5.15.diff | 11 +++++++
3 files changed, 103 insertions(+)
Copied: avidemux/repos/staging-x86_64/PKGBUILD (from rev 388340, avidemux/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2020-06-05 13:58:39 UTC (rev 388341)
@@ -0,0 +1,80 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgbase=avidemux
+pkgname=('avidemux-cli' 'avidemux-qt')
+pkgver=2.7.4
+pkgrel=5
+pkgdesc='Graphical tool to edit video (filter/re-encode/split)'
+url='http://fixounet.free.fr/avidemux/'
+arch=('x86_64')
+license=('GPL2')
+makedepends=('cmake' 'libxslt' 'qt5-base' 'jack' 'libvorbis' 'libxv' 'opus' 'desktop-file-utils'
+ 'alsa-lib' 'lame' 'xvidcore' 'faad2' 'faac' 'x264' 'x265' 'libsamplerate'
+ 'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libpulse' 'libva' 'intltool' 'sqlite'
+ 'libvdpau' 'libdca' 'fribidi' 'glu' 'qt5-tools' 'twolame' 'libfdk-aac' 'libass')
+options=('!emptydirs')
+source=(https://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz
+ log.diff qt-5.15.diff)
+sha256sums=('7db0ac01c8255279a2c360ecb2725c27ea8a2c5bd1f38aeafabfed33ea588da9'
+ '8b751d137037f22fd4ae6750709014bcf61269a18f1c32e1a91f481285c807aa'
+ '255a2446d493503dc237482f6fe26e2186f0ea0ef43ac9e17b8059fe232aad43')
+sha512sums=('e6d0a9eb525d82d0bdecb41b50eaa5894134064148a1889e4bba704d512bb53f871f797444668a0601fecf4e0e61a1f1727b1c59d543860bb64c1a294eb9bf42'
+ 'bbae5b4a549113b12e728c4c0ac8c1c92a0b7500be8dcecc791c16c9a913406feaa9f7bc477985970a920d2df391cc9392457512d84b9c4b829981cc072f2b2e'
+ 'ed78c2a3e4ede4fed1d3ea353c7dc350dc73050f76c8112cb24d97b3eda01f7c186d5db199f71f56953c5e5d8104de44dc0e84e1bfa01b6647c050c11fc375f2')
+
+prepare() {
+ cd ${pkgbase}_${pkgver}
+ patch -Np1 -i ../log.diff # don't hide the build output
+ patch -Np1 -i ../qt-5.15.diff # fix build against Qt 5.15.0
+ sed -i 's|../avidemux/qt4|../avidemux/qt4 -DLRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5|' bootStrap.bash
+ sed -e 's|0.19|1.0|' -i avidemux_plugins/ADM_videoFilters6/ass/CMakeLists.txt
+}
+
+build() {
+ cd ${pkgbase}_${pkgver}
+ bash bootStrap.bash --with-core --with-cli --with-plugins
+}
+
+package_avidemux-cli() {
+ depends=('libxml2' 'fontconfig' 'sqlite' 'libvpx' 'libva' 'libvdpau')
+ optdepends=('lame: for the corresponding audio encoder plugin'
+ 'faac: for the corresponding audio encoder plugin'
+ 'faad2: for the corresponding audio decoder plugin'
+ 'opus: for the corresponding audio decoder plugin'
+ 'opencore-amr: for the corresponding audio decoder plugin'
+ 'jack: for the corresponding audio device plugin'
+ 'libpulse: for the corresponding audio device plugin'
+ 'x264: for the corresponding video encoder plugin'
+ 'libx264: for the corresponding video encoder plugin'
+ 'x265: for the corresponding video encoder plugin'
+ 'xvidcore: for the corresponding video encoder plugin'
+ 'qt5-base: for the QtScript scripting support'
+ 'libdca: for the corresponding audio decoder plugin'
+ 'libfdk-aac: for the corresponding audio decoder plugin'
+ 'twolame: for the corresponding audio decoder plugin'
+ 'libass: for the corresponding video filter plugin'
+ 'fribidi: for the corresponding video filter plugin')
+
+ cd ${pkgbase}_${pkgver}
+ make -C buildCli DESTDIR="${pkgdir}" install
+ make -C buildCore DESTDIR="${pkgdir}" install
+ make -C buildPluginsCLI DESTDIR="${pkgdir}" install
+ make -C buildPluginsCommon DESTDIR="${pkgdir}" install
+
+ install -Dm 644 avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
+ install -Dm 644 man/avidemux.1 -t "${pkgdir}/usr/share/man/man1"
+}
+
+package_avidemux-qt() {
+ pkgdesc='Graphical tool to edit video (filter/re-encode/split) - Qt GUI'
+ depends=("avidemux-cli=${pkgver}" 'qt5-base' 'x264' 'x265' 'glu' 'libxv' 'desktop-file-utils')
+ replaces=('avidemux-gtk')
+
+ cd ${pkgbase}_${pkgver}
+ make -C buildQt5 DESTDIR="${pkgdir}" install
+ make -C buildPluginsQt5 DESTDIR="${pkgdir}" install
+ #install -Dm 644 avidemux-qt.desktop -t "${pkgdir}/usr/share/applications"
+}
+
+# vim: ts=2 sw=2 et:
Copied: avidemux/repos/staging-x86_64/log.diff (from rev 388340, avidemux/trunk/log.diff)
===================================================================
--- staging-x86_64/log.diff (rev 0)
+++ staging-x86_64/log.diff 2020-06-05 13:58:39 UTC (rev 388341)
@@ -0,0 +1,12 @@
+diff -u -r avidemux_2.7.4/bootStrap.bash avidemux_2.7.4-fix/bootStrap.bash
+--- avidemux_2.7.4/bootStrap.bash 2019-08-15 07:25:40.000000000 +0000
++++ avidemux_2.7.4-fix/bootStrap.bash 2020-06-05 13:40:10.633140851 +0000
+@@ -66,7 +66,7 @@
+ fi
+ cd $BUILDDIR
+ cmake $COMPILER $PKG $FAKEROOT $QT_FLAVOR -DCMAKE_EDIT_COMMAND=vim $INSTALL_PREFIX $EXTRA $BUILD_QUIRKS $ASAN $DEBUG -G "$BUILDER" $SOURCEDIR || fail cmakeZ
+- make $PARAL >& /tmp/log$BUILDDIR || fail "make, result in /tmp/log$BUILDDIR"
++ make $PARAL || fail make
+ if [ "x$PKG" != "x" ] ; then
+ $FAKEROOT_COMMAND make package DESTDIR=$FAKEROOT_DIR/tmp || fail package
+ fi
Copied: avidemux/repos/staging-x86_64/qt-5.15.diff (from rev 388340, avidemux/trunk/qt-5.15.diff)
===================================================================
--- staging-x86_64/qt-5.15.diff (rev 0)
+++ staging-x86_64/qt-5.15.diff 2020-06-05 13:58:39 UTC (rev 388341)
@@ -0,0 +1,11 @@
+diff -u -r avidemux_2.7.4/avidemux/qt4/ADM_UIs/src/T_RubberControl.cpp avidemux_2.7.4-fix/avidemux/qt4/ADM_UIs/src/T_RubberControl.cpp
+--- avidemux_2.7.4/avidemux/qt4/ADM_UIs/src/T_RubberControl.cpp 2019-08-15 07:25:39.000000000 +0000
++++ avidemux_2.7.4-fix/avidemux/qt4/ADM_UIs/src/T_RubberControl.cpp 2020-06-05 13:48:28.014061206 +0000
+@@ -8,6 +8,7 @@
+ ***************************************************************************///
+
+ #include <QPainter>
++#include <QPainterPath>
+ #include <QRubberBand>
+ #include <QBoxLayout>
+ #include <QSizeGrip>
More information about the arch-commits
mailing list