[arch-commits] Commit in haskell-resourcet/repos (2 files)

[Felix Yan]

    Date: Sunday, June 7, 2020 @ 20:04:35
  Author: felixonmars
Revision: 640108

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-resourcet/repos/community-staging-x86_64/
  haskell-resourcet/repos/community-staging-x86_64/PKGBUILD
    (from rev 640107, haskell-resourcet/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-resourcet/repos/community-staging-x86_64/PKGBUILD (from rev 640107, haskell-resourcet/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-06-07 20:04:35 UTC (rev 640108)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=resourcet
+pkgname=haskell-resourcet
+pkgver=1.2.4.1
+pkgrel=1
+pkgdesc="Deterministic allocation and freeing of scarce resources."
+url="https://github.com/snoyberg/conduit"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primitive' 'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('451ed385d61e1ebe83b9b6fd892a0bd5e0ee80218096fe583b2b0aaa8bc6514868e276e1c34c7aef8830b472dbc18c11df1d44d7d35f52c84105711c8244356f')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}