[arch-commits] Commit in python-klein/repos/community-any (PKGBUILD PKGBUILD)

Chih-Hsuan Yen yan12125 at archlinux.org
Tue Jun 9 15:55:57 UTC 2020


    Date: Tuesday, June 9, 2020 @ 15:55:56
  Author: yan12125
Revision: 640842

archrelease: copy trunk to community-any

Added:
  python-klein/repos/community-any/PKGBUILD
    (from rev 640841, python-klein/trunk/PKGBUILD)
Deleted:
  python-klein/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   73 ++++++++++++++++++++++++++++---------------------------------
 1 file changed, 34 insertions(+), 39 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-06-09 15:55:42 UTC (rev 640841)
+++ PKGBUILD	2020-06-09 15:55:56 UTC (rev 640842)
@@ -1,39 +0,0 @@
-# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
-# Contributor: xRemaLx <anton.komolov at gmail.com>
-
-pkgname=python-klein
-pkgver=19.6.0
-pkgrel=3
-arch=(any)
-pkgdesc='A web micro-framework built on werkzeug and twisted.web'
-url='https://github.com/twisted/klein'
-license=(MIT)
-# incremental is listed in both setup_requires and install_requires
-depends=(python python-attrs python-hyperlink python-incremental python-six
-         python-tubes python-twisted python-werkzeug python-zope-interface)
-makedepends=(python-setuptools python-incremental)
-checkdepends=(python-hypothesis python-mock python-treq)
-source=("https://github.com/twisted/klein/archive/$pkgver/klein-$pkgver.tar.gz")
-sha512sums=('849631f121449556c33a45dcc5b909339730b50f224cd52aadd1e88b1cfe11ef67c03387ef2fc66517d56251001af161b72b518981d36246c741cc381750858f')
-
-prepare() {
-  cd klein-$pkgver
-  # https://github.com/twisted/klein/pull/286
-  sed -i '/"typing"/d' setup.py
-}
-
-build() {
-  cd klein-$pkgver
-  python setup.py build
-}
-
-check() {
-  cd klein-$pkgver
-  PYTHONPATH=src trial3 klein
-}
-
-package() {
-  cd klein-$pkgver
-  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
-  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
-}

Copied: python-klein/repos/community-any/PKGBUILD (from rev 640841, python-klein/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-06-09 15:55:56 UTC (rev 640842)
@@ -0,0 +1,34 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: xRemaLx <anton.komolov at gmail.com>
+
+pkgname=python-klein
+pkgver=20.6.0
+pkgrel=1
+arch=(any)
+pkgdesc='A web micro-framework built on werkzeug and twisted.web'
+url='https://github.com/twisted/klein'
+license=(MIT)
+depends=(python python-attrs python-hyperlink python-incremental python-six
+         python-tubes python-twisted python-werkzeug python-zope-interface)
+makedepends=(python-setuptools)
+checkdepends=(python-hypothesis python-mock python-treq python-pytest)
+source=("https://github.com/twisted/klein/archive/$pkgver/klein-$pkgver.tar.gz")
+sha512sums=('1cba04a365fd9c7185e2f2472f617f875ee9cec41ac97940dda4a145811cefcbbe34f11e1f306656dc43d88b49e66bfcb5efb72d25283bbc8a0729b2fc5e2fca')
+
+build() {
+  cd klein-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd klein-$pkgver
+  # klein tests are broken with treq 20.4.1
+  # https://github.com/twisted/klein/issues/339
+  pytest -v src/klein/test -k 'not test_customParameterValidation and not test_handlingGET'
+}
+
+package() {
+  cd klein-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}



More information about the arch-commits mailing list