[arch-commits] Commit in (7 files)

[Balló György]

    Date: Tuesday, June 16, 2020 @ 23:25:03
  Author: bgyorgy
Revision: 646268

Add back synfigstudio

Added:
  synfig/
  synfig/trunk/
  synfig/trunk/PKGBUILD
  synfig/trunk/fix-build.patch
  synfigstudio/
  synfigstudio/trunk/
  synfigstudio/trunk/PKGBUILD

------------------------------+
 synfig/trunk/PKGBUILD        |   34 ++++++++++++++++++++++++++++++++++
 synfig/trunk/fix-build.patch |   25 +++++++++++++++++++++++++
 synfigstudio/trunk/PKGBUILD  |   33 +++++++++++++++++++++++++++++++++
 3 files changed, 92 insertions(+)

Added: synfig/trunk/PKGBUILD
===================================================================
--- synfig/trunk/PKGBUILD	                        (rev 0)
+++ synfig/trunk/PKGBUILD	2020-06-16 23:25:03 UTC (rev 646268)
@@ -0,0 +1,34 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Franco Iacomella <yaco at gnu.org>
+
+pkgname=synfig
+pkgver=1.2.2
+pkgrel=3
+pkgdesc="Professional vector animation program (CLI renderer only)"
+arch=(x86_64)
+url="https://www.synfig.org/"
+license=(GPL2)
+depends=(boost-libs fftw imagemagick libjpeg-turbo libmng libxml++2.6 mlt openexr pango)
+makedepends=(boost etl intltool)
+source=(https://downloads.sourceforge.net/synfig/$pkgname-$pkgver.tar.gz
+        fix-build.patch)
+sha256sums=('5f5f7b33483041165f9a63fe4d95eb815971c7444569e574206f6964e83cc2ef'
+            '5f6e6b56a2d55074fb187e48611fbf0ca337e9d4ddd78669e9d836ce6ebedb78')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np2 -i ../fix-build.patch
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --sysconfdir=/etc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}

Added: synfig/trunk/fix-build.patch
===================================================================
--- synfig/trunk/fix-build.patch	                        (rev 0)
+++ synfig/trunk/fix-build.patch	2020-06-16 23:25:03 UTC (rev 646268)
@@ -0,0 +1,25 @@
+From dedb2f7f82a04c0cb3aad462bbe055412f3f5e18 Mon Sep 17 00:00:00 2001
+From: ice0 <konoplin at gmail.com>
+Date: Wed, 29 Aug 2018 12:25:24 +0700
+Subject: [PATCH] Fixed MacOS 10.14 build (removed unnecessary include)
+
+---
+ synfig-core/src/synfig/savecanvas.cpp | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/synfig-core/src/synfig/savecanvas.cpp b/synfig-core/src/synfig/savecanvas.cpp
+index 4335a7bb1..370a389e0 100644
+--- a/synfig-core/src/synfig/savecanvas.cpp
++++ b/synfig-core/src/synfig/savecanvas.cpp
+@@ -66,9 +66,9 @@
+ #include <ETL/stringf>
+ #include "gradient.h"
+ 
+-extern "C" {
++/*extern "C" {
+ #include <libxml/tree.h>
+-}
++}*/
+ 
+ #endif
+ 

Added: synfigstudio/trunk/PKGBUILD
===================================================================
--- synfigstudio/trunk/PKGBUILD	                        (rev 0)
+++ synfigstudio/trunk/PKGBUILD	2020-06-16 23:25:03 UTC (rev 646268)
@@ -0,0 +1,33 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Franco Iacomella <yaco at gnu.org>
+
+pkgname=synfigstudio
+pkgver=1.2.2
+pkgrel=2
+pkgdesc="Professional vector animation program (GUI)"
+arch=(x86_64)
+url="https://www.synfig.org/"
+license=(GPL2)
+depends=(gtkmm3 synfig)
+makedepends=(etl intltool)
+optdepends=('python: for the plugins')
+source=(https://downloads.sourceforge.net/synfig/$pkgname-$pkgver.tar.gz)
+sha256sums=('76fa37998af634cf694f9b5bdfcb90220bc88f8527df117d9282a39fe01489e2')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i 's|appdatadir = $(datadir)/appdata|appdatadir = $(datadir)/metainfo|' Makefile.{am,in}
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --sysconfdir=/etc --disable-update-mimedb
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}