[arch-commits] Commit in krita (4 files)

[Antonio Rojas]

    Date: Wednesday, June 17, 2020 @ 19:40:49
  Author: arojas
Revision: 389448

archrelease: copy trunk to testing-x86_64

Added:
  krita/repos/testing-x86_64/
  krita/repos/testing-x86_64/PKGBUILD
    (from rev 389447, krita/trunk/PKGBUILD)
  krita/repos/testing-x86_64/krita-pyqt5-sip5.patch
    (from rev 389447, krita/trunk/krita-pyqt5-sip5.patch)
Deleted:
  krita/kde-unstable/

------------------------+
 PKGBUILD               |   38 ++++++++++++++++++++++++++++++++++++++
 krita-pyqt5-sip5.patch |   22 ++++++++++++++++++++++
 2 files changed, 60 insertions(+)

Copied: krita/repos/testing-x86_64/PKGBUILD (from rev 389447, krita/trunk/PKGBUILD)
===================================================================
--- repos/testing-x86_64/PKGBUILD	                        (rev 0)
+++ repos/testing-x86_64/PKGBUILD	2020-06-17 19:40:49 UTC (rev 389448)
@@ -0,0 +1,38 @@
+# Maintainer: Antonio Rojas <arojas at archlinux,org>
+
+pkgname=krita
+_pkgver=4.3.0
+pkgver=${_pkgver/-/}
+pkgrel=1
+pkgdesc="Edit and paint images"
+arch=(x86_64)
+url="https://krita.org"
+license=(GPL3)
+depends=(kitemviews kitemmodels ki18n kcompletion kguiaddons kcrash qt5-svg qt5-multimedia quazip
+         gsl libraw exiv2 openexr fftw boost-libs giflib openjpeg2 hicolor-icon-theme)
+makedepends=(extra-cmake-modules kdoctools boost eigen vc poppler-qt5 opencolorio python-pyqt5 libheif
+             qt5-tools sip python-sip)
+optdepends=('poppler-qt5: PDF filter' 'ffmpeg: to save animations' 'opencolorio: for the LUT docker'
+            "krita-plugin-gmic: G'MIC plugin" 'python-pyqt5: for the Python plugins' 'libheif: HEIF filter')
+conflicts=(calligra-krita krita-l10n)
+replaces=(calligra-krita krita-l10n)
+source=("https://download.kde.org/stable/krita/$_pkgver/$pkgname-$_pkgver.tar.gz"
+         krita-pyqt5-sip5.patch)
+sha256sums=('d071887c73bffbdc179054826b9752f5e5ab43fdcd9ffdd0402e9ab2ceee4bda'
+            'ab2f33843d8cad31bc13e0eca7dc732cdbfed054924f25ed61102c0d0971c1d8')
+validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD') # Boudewijn Rempt <foundation at krita.org>
+
+prepare() {
+  patch -d $pkgname-$_pkgver -p1 -i ../krita-pyqt5-sip5.patch # Fix sip include dir when PyQt5 is compiled with SIP 5
+}
+
+build() {
+  cmake -B build -S $pkgname-$_pkgver \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_KRITA_QT_DESIGNER_PLUGINS=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}

Copied: krita/repos/testing-x86_64/krita-pyqt5-sip5.patch (from rev 389447, krita/trunk/krita-pyqt5-sip5.patch)
===================================================================
--- repos/testing-x86_64/krita-pyqt5-sip5.patch	                        (rev 0)
+++ repos/testing-x86_64/krita-pyqt5-sip5.patch	2020-06-17 19:40:49 UTC (rev 389448)
@@ -0,0 +1,22 @@
+diff --git a/cmake/modules/FindPyQt5.py b/cmake/modules/FindPyQt5.py
+index 5849f40868..a42ba6c624 100644
+--- a/cmake/modules/FindPyQt5.py
++++ b/cmake/modules/FindPyQt5.py
+@@ -2,7 +2,7 @@
+ # Redistribution and use is allowed according to the terms of the BSD license.
+ # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+ 
+-import sys
++import sys, site
+ import os
+ 
+ try:
+@@ -41,7 +41,7 @@ except ValueError:
+     pass
+ 
+ # FIXME This next line is just a little bit too crude.
+-pyqt_sip_dir = os.path.join(sys.prefix, "share", "sip", "PyQt5")
++pyqt_sip_dir = os.path.join(site.getsitepackages()[0], "PyQt5", "bindings")
+ print("pyqt_sip_dir:%s" % pyqt_sip_dir)
+ 
+ print("pyqt_sip_flags:%s" % PyQt5.QtCore.PYQT_CONFIGURATION["sip_flags"])