[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Fri Jun 19 20:44:32 UTC 2020
Date: Friday, June 19, 2020 @ 20:44:32
Author: felixonmars
Revision: 389550
addpkg: python-resolvelib 0.4.0-1
Added:
python-resolvelib/
python-resolvelib/repos/
python-resolvelib/trunk/
python-resolvelib/trunk/PKGBUILD
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Added: python-resolvelib/trunk/PKGBUILD
===================================================================
--- python-resolvelib/trunk/PKGBUILD (rev 0)
+++ python-resolvelib/trunk/PKGBUILD 2020-06-19 20:44:32 UTC (rev 389550)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-resolvelib
+pkgname=(python-resolvelib python2-resolvelib)
+pkgver=0.4.0
+pkgrel=1
+pkgdesc="Resolve abstract dependencies into concrete ones"
+url="https://github.com/sarugaku/resolvelib"
+license=('ISC')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-commentjson' 'python-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/sarugaku/resolvelib/archive/$pkgver.tar.gz")
+sha512sums=('461b50f37354d8323df1a634bda16d047f2a58eea62df23201e630ffb293be1d6d0860550798617573849bb72fc1c22fd94cea0c7d5fb804a38e41bb4dc697e3')
+
+build() {
+ cd resolvelib-$pkgver
+ python setup.py build
+ python2 setup.py build
+}
+
+check() {
+ cd resolvelib-$pkgver
+ python setup.py pytest
+}
+
+package_python-resolvelib() {
+ depends=('python')
+
+ cd resolvelib-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+}
+
+package_python2-resolvelib() {
+ depends=('python2')
+
+ cd resolvelib-$pkgver
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+}
More information about the arch-commits
mailing list