[arch-commits] Commit in xmobar/repos (2 files)

[Felix Yan]

    Date: Sunday, June 21, 2020 @ 13:40:01
  Author: felixonmars
Revision: 649299

archrelease: copy trunk to community-staging-x86_64

Added:
  xmobar/repos/community-staging-x86_64/
  xmobar/repos/community-staging-x86_64/PKGBUILD
    (from rev 649298, xmobar/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: xmobar/repos/community-staging-x86_64/PKGBUILD (from rev 649298, xmobar/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-06-21 13:40:01 UTC (rev 649299)
@@ -0,0 +1,63 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=xmobar
+pkgver=0.34
+pkgrel=6
+pkgdesc='Minimalistic Text Based Status Bar'
+url='https://hackage.haskell.org/package/xmobar'
+license=('BSD')
+arch=('x86_64')
+depends=('libxft' 'libxinerama' 'libxrandr' 'libxpm' 'ghc-libs' 'haskell-x11'
+         'haskell-x11-xft' 'haskell-utf8-string' 'haskell-network-uri'
+         'haskell-hinotify' 'haskell-stm' 'haskell-parsec' 'haskell-parsec-numbers'
+         'haskell-mtl' 'haskell-regex-base' 'haskell-regex-compat'
+         'haskell-http' 'haskell-dbus' 'haskell-libmpd' 'haskell-cereal' 'haskell-netlink'
+         'haskell-text' 'haskell-async' 'haskell-aeson'
+         'haskell-timezone-olson' 'haskell-timezone-series' 'alsa-lib'
+         'haskell-extensible-exceptions' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-http-client-tls' 'haskell-alsa-core' 'haskell-alsa-mixer')
+makedepends=('ghc' 'haskell-hspec' 'haskell-temporary')
+source=(https://github.com/jaor/xmobar/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('35c4efda4fceb64168cde23392aa6953c68b3779f56b4c3a7776fa3561ba2d5f40794645f137382f34ea6f7fc96d9d126d58cd2719e5459aaffbca25676336cb')
+
+prepare() {
+  cd xmobar-$pkgver
+  sed -e 's/&& <.*,/,/g' -e 's/==.*,/,/g' -i xmobar.cabal
+}
+
+build() {
+  cd xmobar-${pkgver}
+
+  _flags=(with_xft with_utf8 with_inotify with_mpd with_alsa with_nl80211
+          with_datezone with_mpris with_dbus with_xpm with_threaded
+          with_rtsopts with_weather)
+
+  runhaskell setup configure -O \
+    --enable-shared \
+    --enable-executable-dynamic \
+    --disable-library-vanilla \
+    --prefix=/usr \
+    --dynlibdir=/usr/lib \
+    --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' \
+    --flags="${_flags[*]}" \
+    --enable-tests
+  runhaskell setup build
+}
+
+check() {
+  cd xmobar-${pkgver}
+  runhaskell setup test
+}
+
+package() {
+  cd xmobar-${pkgver}
+  runhaskell setup copy --destdir="${pkgdir}"
+  install -Dm 644 license -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: