[arch-commits] Commit in perl-alien-sdl/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Sunday, June 21, 2020 @ 15:24:56
  Author: foutrelis
Revision: 389852

archrelease: copy trunk to staging-x86_64

Added:
  perl-alien-sdl/repos/staging-x86_64/
  perl-alien-sdl/repos/staging-x86_64/PKGBUILD
    (from rev 389851, perl-alien-sdl/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: perl-alien-sdl/repos/staging-x86_64/PKGBUILD (from rev 389851, perl-alien-sdl/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-06-21 15:24:56 UTC (rev 389852)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Sarah Hay <sarahhay at mb.sympatico.ca>
+
+# This package must not by "any" arch.
+# Requires rebuild with every change to sdl-config
+
+pkgname=perl-alien-sdl
+_realname=Alien-SDL
+pkgver=1.446
+pkgrel=10
+pkgdesc="Building, finding and using SDL binaries"
+arch=(x86_64)
+license=(PerlArtistic GPL)
+url="https://metacpan.org/release/$_realname"
+depends=('sdl=1.2.15' perl-file-sharedir perl-capture-tiny)
+makedepends=(perl-file-which perl-text-patch perl-archive-extract perl-archive-zip perl-module-build)
+options=(!emptydirs)
+source=("https://cpan.metacpan.org/authors/id/F/FR/FROGGS/$_realname-$pkgver.tar.gz")
+sha256sums=('c9aa2c9dc3c63d89773c7d7203f2a46d1b924d0c72d9f801af147a3dc8bc512a')
+
+prepare() {
+  cd $_realname-$pkgver
+
+  # Workaround bug with --with-sdl-config
+  sed -i '/^GetOptions/d' Build.PL
+}
+
+build() {
+  cd $_realname-$pkgver
+
+  # install module in vendor directories
+  perl Build.PL --with-sdl-config
+  perl Build
+}
+
+package() {
+  cd $_realname-$pkgver
+  perl Build install installdirs=vendor destdir="$pkgdir"
+}
+
+# vim:set sw=2 et: