[arch-commits] Commit in python-scipy/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Sun Jun 21 22:16:30 UTC 2020
Date: Sunday, June 21, 2020 @ 22:16:19
Author: arojas
Revision: 650299
archrelease: copy trunk to community-testing-x86_64
Added:
python-scipy/repos/community-testing-x86_64/
python-scipy/repos/community-testing-x86_64/PKGBUILD
(from rev 650298, python-scipy/trunk/PKGBUILD)
----------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
Copied: python-scipy/repos/community-testing-x86_64/PKGBUILD (from rev 650298, python-scipy/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2020-06-21 22:16:19 UTC (rev 650299)
@@ -0,0 +1,57 @@
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+
+_name=scipy
+pkgname=python-scipy
+pkgver=1.5.0
+pkgrel=1
+pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
+arch=('x86_64')
+url="https://www.scipy.org/"
+license=('BSD')
+depends=('python-numpy')
+provides=('python3-scipy' 'scipy')
+makedepends=('gcc-fortran' 'python-setuptools' 'pybind11')
+checkdepends=('python-pytest')
+optdepends=('python-pillow: for image saving module')
+#source=("https://github.com/scipy/scipy/releases/download/v${pkgver}/scipy-${pkgver}.tar.xz")
+source=("https://pypi.python.org/packages/source/${_name:0:1}/${_name}/${_name}-${pkgver}.tar.gz")
+sha512sums=('4c981a3125a88593cbc5a17417022a5db8f6ccb4c1c24e78afeb9bb26428b81d2d0fe9965caa418753b1bbbda2fa30533fa1307aac6ab168458d68f7b46049be')
+
+build() {
+ # required for gfortran
+ export LDFLAGS="-Wall -shared"
+
+ cd scipy-${pkgver}
+ python setup.py config_fc --fcompiler=gnu95 build
+}
+
+check() {
+ # we need to do a temp install so we can import scipy
+ # also, the tests must not be run from the scipy source directory
+ export LDFLAGS="-Wall -shared"
+
+ cd scipy-${pkgver}
+ python3 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root=${srcdir}/test --optimize=1
+ export PYTHONPATH=${srcdir}/test/usr/lib/python3.8/site-packages
+ cd "${srcdir}"
+ python -c "from scipy import test; test('full')"
+}
+
+package() {
+ export LDFLAGS="-Wall -shared"
+
+ cd scipy-${pkgver}
+ python3 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root="${pkgdir}" --optimize=1
+
+ install -Dm644 LICENSE.txt \
+ "${pkgdir}/usr/share/licenses/python-scipy/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list