[arch-commits] Commit in harfbuzz/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Jan Steffens heftig at archlinux.org
Mon Jun 22 21:38:16 UTC 2020


    Date: Monday, June 22, 2020 @ 21:38:15
  Author: heftig
Revision: 390138

archrelease: copy trunk to extra-x86_64

Added:
  harfbuzz/repos/extra-x86_64/PKGBUILD
    (from rev 390137, harfbuzz/trunk/PKGBUILD)
Deleted:
  harfbuzz/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  138 ++++++++++++++++++++++++++++---------------------------------
 1 file changed, 64 insertions(+), 74 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-06-22 21:38:05 UTC (rev 390137)
+++ PKGBUILD	2020-06-22 21:38:15 UTC (rev 390138)
@@ -1,74 +0,0 @@
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-
-pkgbase=harfbuzz
-pkgname=(harfbuzz harfbuzz-icu)
-pkgver=2.6.7
-pkgrel=1
-pkgdesc="OpenType text shaping engine"
-url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
-arch=(x86_64)
-license=(MIT)
-makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
-             ragel git python)
-checkdepends=(python-fonttools python-setuptools)
-_commit=fb46a32ed0322d3f617dbfc7b982ff26f47d789c  # tags/2.6.7^0
-source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd harfbuzz
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd harfbuzz
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd harfbuzz
-  ./configure \
-    --prefix=/usr \
-    --with-cairo \
-    --with-freetype \
-    --with-glib \
-    --with-gobject \
-    --with-graphite2 \
-    --with-icu \
-    --enable-gtk-doc
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-  make
-}
-
-check() {
-  cd harfbuzz
-  TMPDIR="$srcdir" make check
-  rm -rf "$srcdir"/tmp*
-}
-
-package_harfbuzz() {
-  depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
-           libgobject-2.0.so)
-  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
-  optdepends=('cairo: hb-view program')
-
-  cd harfbuzz
-  make DESTDIR="$pkgdir" install
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
-
-# Split harfbuzz-icu
-  mkdir -p ../hb-icu/usr/{include/harfbuzz,lib/pkgconfig}; cd ../hb-icu
-  mv "$pkgdir"/usr/lib/libharfbuzz-icu* ./usr/lib
-  mv "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc ./usr/lib/pkgconfig
-  mv "$pkgdir"/usr/include/harfbuzz/hb-icu.h ./usr/include/harfbuzz
-}
-
-package_harfbuzz-icu() {
-  pkgdesc="$pkgdesc (ICU integration)"
-  depends=("harfbuzz=$pkgver-$pkgrel" icu libharfbuzz.so)
-  provides=(libharfbuzz-icu.so)
-
-  mv hb-icu/* "$pkgdir"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
-}

Copied: harfbuzz/repos/extra-x86_64/PKGBUILD (from rev 390137, harfbuzz/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-06-22 21:38:15 UTC (rev 390138)
@@ -0,0 +1,64 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=harfbuzz
+pkgname=(harfbuzz harfbuzz-icu)
+pkgver=2.6.8
+pkgrel=1
+pkgdesc="OpenType text shaping engine"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
+             ragel git python meson)
+checkdepends=(python-fonttools python-setuptools)
+_commit=e4203c14699cc0903a2b4611167a7b99532cfdb0  # tags/2.6.8^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd harfbuzz
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd harfbuzz
+}
+
+build() {
+  arch-meson harfbuzz build \
+    -D graphite=enabled
+  meson compile -C build
+}
+
+check() {
+  TMPDIR="$srcdir" meson test -C build --print-errorlogs
+  rm -rf "$srcdir"/tmp*
+}
+
+package_harfbuzz() {
+  depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
+           libgobject-2.0.so)
+  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+  optdepends=('cairo: hb-view program')
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  # Split harfbuzz-icu
+  mkdir -p hb-icu/usr/{include/harfbuzz,lib/pkgconfig}
+  mv -t hb-icu/usr/lib "$pkgdir"/usr/lib/libharfbuzz-icu*
+  mv -t hb-icu/usr/lib/pkgconfig "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc
+  mv -t hb-icu/usr/include/harfbuzz "$pkgdir"/usr/include/harfbuzz/hb-icu.h
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_harfbuzz-icu() {
+  pkgdesc="$pkgdesc (ICU integration)"
+  depends=("harfbuzz=$pkgver-$pkgrel" icu libharfbuzz.so)
+  provides=(libharfbuzz-icu.so)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}


More information about the arch-commits mailing list