[arch-commits] Commit in haskell-typed-process/repos (2 files)

[Felix Yan]

    Date: Tuesday, June 23, 2020 @ 23:26:50
  Author: felixonmars
Revision: 651902

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-typed-process/repos/community-staging-x86_64/
  haskell-typed-process/repos/community-staging-x86_64/PKGBUILD
    (from rev 651901, haskell-typed-process/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-typed-process/repos/community-staging-x86_64/PKGBUILD (from rev 651901, haskell-typed-process/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-06-23 23:26:50 UTC (rev 651902)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=typed-process
+pkgname=haskell-typed-process
+pkgver=0.2.6.0
+pkgrel=33
+pkgdesc="Run external processes, with strong typing of streams"
+url="https://haskell-lang.org/library/typed-process"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-base64-bytestring' 'haskell-hspec' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a40b8db4ef2179273943a3aab0200891bd3dffe584bcd51037ddf9cebae88d4d95292883a745a0c31900c7bf2eebe2c71175fbb86dc470b60660b443f8b1e3e0')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}