[arch-commits] Commit in hoogle/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Jun 26 03:35:33 UTC 2020


    Date: Friday, June 26, 2020 @ 03:35:32
  Author: felixonmars
Revision: 653410

archrelease: copy trunk to community-staging-x86_64

Added:
  hoogle/repos/community-staging-x86_64/
  hoogle/repos/community-staging-x86_64/PKGBUILD
    (from rev 653409, hoogle/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: hoogle/repos/community-staging-x86_64/PKGBUILD (from rev 653409, hoogle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-06-26 03:35:32 UTC (rev 653410)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hoogle
+pkgver=5.0.17.15
+pkgrel=77
+pkgdesc="Haskell API Search"
+url="https://www.haskell.org/hoogle/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-cmdargs' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-connection' 'haskell-extra' 'haskell-foundation' 'haskell-hashable'
+         'haskell-http-conduit' 'haskell-http-types' 'haskell-js-flot' 'haskell-js-jquery'
+         'haskell-mmap' 'haskell-network' 'haskell-old-locale' 'haskell-process-extras'
+         'haskell-resourcet' 'haskell-src-exts' 'haskell-storable-tuple' 'haskell-tar'
+         'haskell-uniplate' 'haskell-utf8-string' 'haskell-vector' 'haskell-wai'
+         'haskell-wai-logger' 'haskell-warp' 'haskell-warp-tls' 'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('e2440cc92f5395e0e6b25344d0ed47eaa20ab257d2e9d5d3f67005d3ed666acc359503516418127cb3fe9a760387105b7894de80fafea326fe75143022ec5283')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+        --ghc-option='-pie'
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list