[arch-commits] Commit in python-idna/repos (testing-any testing-any/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Sun Jun 28 20:24:37 UTC 2020
Date: Sunday, June 28, 2020 @ 20:24:37
Author: felixonmars
Revision: 390552
archrelease: copy trunk to testing-any
Added:
python-idna/repos/testing-any/
python-idna/repos/testing-any/PKGBUILD
(from rev 390551, python-idna/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: python-idna/repos/testing-any/PKGBUILD (from rev 390551, python-idna/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD (rev 0)
+++ testing-any/PKGBUILD 2020-06-28 20:24:37 UTC (rev 390552)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-idna
+pkgname=('python-idna' 'python2-idna')
+pkgver=2.10
+pkgrel=1
+pkgdesc="Internationalized Domain Names in Applications (IDNA)"
+arch=('any')
+license=('BSD')
+url="https://github.com/kjd/idna"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("https://pypi.io/packages/source/i/idna/idna-$pkgver.tar.gz")
+sha512sums=('83b412de2f79a4bc86fb4bdac7252521b9d84f0be54f4fb1bde1ee13a210bbfa4b1a98247affbc7921046fb117a591316c12694c1be72865767646554c5207ac')
+
+prepare() {
+ rm -r idna-$pkgver/*.egg-info
+ cp -a idna-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/idna-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/idna-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/idna-$pkgver
+ python setup.py test
+
+ cd "$srcdir"/idna-$pkgver-py2
+ python2 setup.py test
+}
+
+package_python-idna() {
+ depends=('python')
+
+ cd idna-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
+
+package_python2-idna() {
+ depends=('python2')
+
+ cd idna-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
More information about the arch-commits
mailing list