[arch-commits] Commit in libmicrohttpd/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Christian Hesse]

    Date: Sunday, June 28, 2020 @ 20:29:06
  Author: eworm
Revision: 390555

archrelease: copy trunk to testing-x86_64

Added:
  libmicrohttpd/repos/testing-x86_64/
  libmicrohttpd/repos/testing-x86_64/PKGBUILD
    (from rev 390554, libmicrohttpd/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: libmicrohttpd/repos/testing-x86_64/PKGBUILD (from rev 390554, libmicrohttpd/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-06-28 20:29:06 UTC (rev 390555)
@@ -0,0 +1,45 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Norberto Lopes <shelika at mail.telepac.pt>
+# Contributor: Kao Dome <kaodome at gmail.com>
+# Contributor: Dmitrij D. Czarkoff <czarkoff at gmail.com>
+# Contributor: Mathias Rohnstock <linksoft at gmx.de>
+
+pkgname=libmicrohttpd
+pkgver=0.9.71
+pkgrel=1
+pkgdesc="a small C library that is supposed to make it easy to run an HTTP server as part of another application."
+arch=('x86_64')
+url="https://www.gnu.org/software/libmicrohttpd/"
+license=('LGPL')
+depends=('gnutls')
+checkdepends=('curl')
+provides=('libmicrohttpd.so')
+validpgpkeys=('EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'  # Evgeny Grin (Karlson2k) <k2k at yandex.ru>
+              'D8423BCB326C7907033929C7939E6BE1E29FC3CC') # Christian Grothoff <christian.grothoff at bfh.ch>
+source=("https://ftp.gnu.org/gnu/libmicrohttpd/$pkgname-$pkgver.tar.gz"{,.sig})
+sha256sums=('e8f445e85faf727b89e9f9590daea4473ae00ead38b237cf1eda55172b89b182'
+            'SKIP')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --disable-dependency-tracking \
+    --disable-examples \
+    --enable-curl \
+    --enable-https \
+    --enable-largefile \
+    --enable-messages \
+    --with-pic
+  make
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  make check
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="$pkgdir" install
+}