[arch-commits] Commit in (4 files)
Frederik Schwan
freswa at archlinux.org
Tue Jun 30 04:15:23 UTC 2020
Date: Tuesday, June 30, 2020 @ 04:15:22
Author: freswa
Revision: 657046
libpurple-lurch: move from unsupported to community
Added:
libpurple-lurch/
libpurple-lurch/repos/
libpurple-lurch/trunk/
libpurple-lurch/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: libpurple-lurch/trunk/PKGBUILD
===================================================================
--- libpurple-lurch/trunk/PKGBUILD (rev 0)
+++ libpurple-lurch/trunk/PKGBUILD 2020-06-30 04:15:22 UTC (rev 657046)
@@ -0,0 +1,42 @@
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+
+pkgname=libpurple-lurch
+pkgver=0.6.8
+pkgrel=4
+pkgdesc='Plugin for libpurple (Pidgin, Adium, etc) implementing OMEMO (using axolotl)'
+arch=('x86_64')
+url='https://github.com/gkdr/lurch'
+license=('GPL')
+makedepends=('cmake' 'git')
+depends=('libpurple' 'mxml' 'libxml2' 'sqlite' 'libgcrypt')
+optdepends=('libpurple-carbons: message carbons support')
+source=("git+https://github.com/gkdr/lurch.git#tag=v${pkgver}"
+ 'git+https://github.com/gkdr/axc'
+ 'git+https://github.com/gkdr/libomemo'
+ 'git+https://github.com/WhisperSystems/libsignal-protocol-c.git')
+b2sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP')
+
+prepare() {
+ cd ${pkgname##libpurple-}
+ git submodule init
+ git config submodule.'lib/axc'.url "${srcdir}"/axc
+ git config submodule.'lib/libomemo'.url "${srcdir}"/libomemo
+ git submodule update --recursive
+ cd lib/axc
+ git config submodule.'lib/libsignal-protocol-c'.url "${srcdir}"/libsignal-protocol-c
+ cd "${srcdir}"/${pkgname##libpurple-}
+ git submodule update --recursive
+}
+
+build() {
+ cd ${pkgname##libpurple-}
+ make
+}
+
+package() {
+ cd ${pkgname##libpurple-}
+ make DESTDIR="${pkgdir}" install
+}
More information about the arch-commits
mailing list