[arch-commits] Commit in libpurple-lurch/repos (2 files)

Frederik Schwan freswa at archlinux.org
Tue Jun 30 04:17:47 UTC 2020


    Date: Tuesday, June 30, 2020 @ 04:17:47
  Author: freswa
Revision: 657047

archrelease: copy trunk to community-x86_64

Added:
  libpurple-lurch/repos/community-x86_64/
  libpurple-lurch/repos/community-x86_64/PKGBUILD
    (from rev 657046, libpurple-lurch/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: libpurple-lurch/repos/community-x86_64/PKGBUILD (from rev 657046, libpurple-lurch/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-06-30 04:17:47 UTC (rev 657047)
@@ -0,0 +1,42 @@
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+
+pkgname=libpurple-lurch
+pkgver=0.6.8
+pkgrel=4
+pkgdesc='Plugin for libpurple (Pidgin, Adium, etc) implementing OMEMO (using axolotl)'
+arch=('x86_64')
+url='https://github.com/gkdr/lurch'
+license=('GPL')
+makedepends=('cmake' 'git')
+depends=('libpurple' 'mxml' 'libxml2' 'sqlite' 'libgcrypt')
+optdepends=('libpurple-carbons: message carbons support')
+source=("git+https://github.com/gkdr/lurch.git#tag=v${pkgver}"
+        'git+https://github.com/gkdr/axc'
+        'git+https://github.com/gkdr/libomemo'
+        'git+https://github.com/WhisperSystems/libsignal-protocol-c.git')
+b2sums=('SKIP'
+        'SKIP'
+        'SKIP'
+        'SKIP')
+
+prepare() {
+  cd ${pkgname##libpurple-}
+  git submodule init
+  git config submodule.'lib/axc'.url "${srcdir}"/axc
+  git config submodule.'lib/libomemo'.url "${srcdir}"/libomemo
+  git submodule update --recursive
+  cd lib/axc
+  git config submodule.'lib/libsignal-protocol-c'.url "${srcdir}"/libsignal-protocol-c
+  cd "${srcdir}"/${pkgname##libpurple-}
+  git submodule update --recursive
+}
+
+build() {
+  cd ${pkgname##libpurple-}
+  make
+}
+
+package() {
+  cd ${pkgname##libpurple-}
+  make DESTDIR="${pkgdir}" install
+}



More information about the arch-commits mailing list