[arch-commits] Commit in notion/repos (3 files)

[Evangelos Foutras]

    Date: Tuesday, June 30, 2020 @ 05:03:26
  Author: foutrelis
Revision: 657062

archrelease: copy trunk to community-staging-x86_64

Added:
  notion/repos/community-staging-x86_64/
  notion/repos/community-staging-x86_64/ChangleLog
    (from rev 657061, notion/trunk/ChangleLog)
  notion/repos/community-staging-x86_64/PKGBUILD
    (from rev 657061, notion/trunk/PKGBUILD)

------------+
 ChangleLog |    5 ++
 PKGBUILD   |  117 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 122 insertions(+)

Copied: notion/repos/community-staging-x86_64/ChangleLog (from rev 657061, notion/trunk/ChangleLog)
===================================================================
--- community-staging-x86_64/ChangleLog	                        (rev 0)
+++ community-staging-x86_64/ChangleLog	2020-06-30 05:03:26 UTC (rev 657062)
@@ -0,0 +1,5 @@
+2011-09-14 Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+	* 20110914-1 :
+	Add contrib/ to /usr/share/notion/contrib
+	Add mod_*.lua to /etc/notion/

Copied: notion/repos/community-staging-x86_64/PKGBUILD (from rev 657061, notion/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-06-30 05:03:26 UTC (rev 657062)
@@ -0,0 +1,117 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Eugen Zagorodniy e dot zagorodniy at gmail dot com
+# Contributor: aunoor
+
+pkgname=notion
+epoch=1
+pkgver=4.0.0
+pkgrel=2
+_commit_doc=3c3703c60c79cc0494e664aa83fc880f1285a45b
+pkgdesc="Tabbed tiling, window manager. Fork of Ion3"
+url="https://notionwm.net"
+arch=('x86_64')
+license=('LGPL')
+depends=('glib2' 'gettext' 'lua' 'libxext' 'libsm' 'freetype2')
+optdepends=('libxinerama' 'libxrandr')
+makedepends=('git' 'pkgconfig' 'libxinerama' 'libxrandr'
+	     'rubber' 'latex2html' 'texlive-htmlxml' 'texlive-latexextra')
+backup=("etc/notion/cfg_defaults.lua"
+	"etc/notion/cfg_dock.lua"
+	"etc/notion/cfg_kludges.lua"
+	"etc/notion/cfg_layouts.lua"
+	"etc/notion/cfg_menu.lua"
+	"etc/notion/cfg_notion.lua"
+	"etc/notion/cfg_notioncore.lua"
+	"etc/notion/cfg_query.lua"
+	"etc/notion/cfg_sp.lua"
+	"etc/notion/cfg_statusbar.lua"
+	"etc/notion/cfg_tiling.lua"
+	"etc/notion/cfg_xrandr.lua"
+	"etc/notion/look.lua"
+	"etc/notion/look_brownsteel.lua"
+	"etc/notion/look_clean.lua"
+	"etc/notion/look_cleanios.lua"
+	"etc/notion/look_cleanviolet.lua"
+	"etc/notion/look_dusky.lua"
+	"etc/notion/look_greenlight.lua"
+	"etc/notion/look_greyviolet.lua"
+	"etc/notion/look_ios.lua"
+	"etc/notion/look_newviolet.lua"
+	"etc/notion/look_simpleblue.lua"
+	"etc/notion/lookcommon_clean.lua"
+	"etc/notion/lookcommon_emboss.lua"
+	"etc/notion/mod_xinerama.lua"
+	"etc/notion/statusbar_xkbgroup.lua"
+	"etc/notion/test_xinerama.lua"
+	"etc/notion/xkbbell.lua"
+	"etc/notion/xkbion.lua")
+provides=('libtu' 'libextl')
+changelog=ChangleLog
+source=("notion::git://github.com/raboof/notion#tag=${pkgver}"
+	"notion-doc::git://github.com/raboof/notion-doc.git#commit=${_commit_doc}")
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd "$srcdir"
+  cat >notion/build/lua-detect.mk <<EOF
+LUA_VERSION := 5.3
+LUA_LIBS     := $(pkg-config --libs lua)
+LUA_INCLUDES := $(pkg-config --cflags lua)
+LUA          := $(which lua)
+LUAC         := $(which luac)
+EOF
+  sed -i '/Skipping dvi and ps because/d' notion-doc/Makefile
+}
+
+build() {
+  cd "$srcdir"/notion
+  make \
+	INCLUDES="-I$srcdir/notion -I/usr/include/freetype2" \
+	LUA_VERSION=5.3 \
+	PREFIX=/usr \
+	ETCDIR=/etc/notion
+
+  cd "$srcdir"/notion-doc
+  make all-html all-html-onepage
+}
+
+package() {
+  cd "$srcdir"/notion
+  make \
+	DESTDIR="$pkgdir" \
+	LUA_VERSION=5.3 \
+	PREFIX=/usr \
+	ETCDIR=/etc/notion \
+	install
+
+  # doc
+  cd "$srcdir"/notion-doc
+  make PREFIX="$pkgdir"/usr ETCDIR=/etc/notion install
+
+  # fix typo
+  mv "$pkgdir"/usr/share/notion/notion{,flux}.1 "$pkgdir"/usr/share/man/man1/
+
+  # modules
+  cp "$srcdir"/notion/mod_xinerama/*.lua "$pkgdir"/etc/notion/
+  cp "$srcdir"/notion/mod_xkbevents/*.lua "$pkgdir"/etc/notion/
+
+  # contrib
+  mkdir -p "$pkgdir"/usr/share/notion/contrib
+  cp -a "$srcdir"/$pkgname/contrib/* "$pkgdir"/usr/share/notion/contrib
+
+  # license
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/notion/LICENSE
+
+  #
+  mkdir -p "$pkgdir"/usr/share/xsessions
+  cat >"$pkgdir"/usr/share/xsessions/notion.desktop <<EOF
+[Desktop Entry]
+Name=Notion
+Comment=This session logs you into Notion
+Exec=/usr/bin/notion
+TryExec=/usr/bin/notion
+Icon=
+Type=XSession
+EOF
+}