[arch-commits] Commit in haskell-attoparsec-iso8601/repos (2 files)

[Felix Yan]

    Date: Sunday, March 1, 2020 @ 17:34:50
  Author: felixonmars
Revision: 587816

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-attoparsec-iso8601/repos/community-staging-x86_64/
  haskell-attoparsec-iso8601/repos/community-staging-x86_64/PKGBUILD
    (from rev 587815, haskell-attoparsec-iso8601/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-attoparsec-iso8601/repos/community-staging-x86_64/PKGBUILD (from rev 587815, haskell-attoparsec-iso8601/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-01 17:34:50 UTC (rev 587816)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=attoparsec-iso8601
+pkgname=haskell-attoparsec-iso8601
+pkgver=1.0.1.0
+pkgrel=53
+pkgdesc="Parsing of ISO 8601 dates, originally from aeson"
+url="https://github.com/bos/aeson"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-compat')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a1d751d388446a7d2f628d7112b72beab338061bf2f8dc74c26549f0e93ebbb955bd9082db8a70db71cd80ceb576b22a94195c34f816eb6cecd5c584cb100e8b')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *0.11/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-developer -f-fast
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}