[arch-commits] Commit in haskell-criterion/repos (2 files)

[Felix Yan]

    Date: Monday, March 2, 2020 @ 12:57:29
  Author: felixonmars
Revision: 588461

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-criterion/repos/community-staging-x86_64/
  haskell-criterion/repos/community-staging-x86_64/PKGBUILD
    (from rev 588460, haskell-criterion/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-criterion/repos/community-staging-x86_64/PKGBUILD (from rev 588460, haskell-criterion/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-02 12:57:29 UTC (rev 588461)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=criterion
+pkgname=haskell-criterion
+pkgver=1.5.6.0
+pkgrel=23
+pkgdesc="Robust, reliable performance measurement and analysis"
+url="http://www.serpentine.com/criterion"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-wl-pprint' 'haskell-base-compat-batteries'
+         'haskell-binary-orphans' 'haskell-cassava' 'haskell-code-page'
+         'haskell-criterion-measurement' 'haskell-exceptions' 'haskell-glob' 'haskell-js-flot'
+         'haskell-js-jquery' 'haskell-microstache' 'haskell-mwc-random'
+         'haskell-optparse-applicative' 'haskell-statistics' 'haskell-transformers-compat'
+         'haskell-vector' 'haskell-vector-algorithms')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-hunit' 'haskell-quickcheck' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c512a5d80e3257823f3ff53204f7198283b660fc1adc60b76f75e88fd2e03956b5085f820915dc44e2518d5f84c04ee41ff4d35198544daac583ce6ff672c571')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/>= *1.0/>=0/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-fast -f-embed-data-files
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}