[arch-commits] Commit in stylish-haskell/repos (2 files)

[Felix Yan]

    Date: Monday, March 2, 2020 @ 20:14:13
  Author: felixonmars
Revision: 588729

archrelease: copy trunk to community-staging-x86_64

Added:
  stylish-haskell/repos/community-staging-x86_64/
  stylish-haskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 588728, stylish-haskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: stylish-haskell/repos/community-staging-x86_64/PKGBUILD (from rev 588728, stylish-haskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-02 20:14:13 UTC (rev 588729)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=stylish-haskell
+pkgver=0.11.0.0
+pkgrel=5
+pkgdesc="Haskell code prettifier"
+url="https://github.com/jaspervdj/stylish-haskell"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-file-embed' 'haskell-optparse-applicative'
+         'haskell-src-exts' 'haskell-strict' 'haskell-syb' 'haskell-hsyaml' 'haskell-hsyaml-aeson')
+makedepends=('ghc' 'haskell-hunit' 'haskell-random' 'haskell-test-framework'
+             'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('3939fb8d88b77b75983c95770190c23f04ae3f00c7f4c826e8ec3898a9be6f3816df6e9398a9f5932e88c86d2bdaa7ef096c8063738cafd5c8de2ebd0ba5da25')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e '/semigroups/d' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old_base --ghc-option='-pie'
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}