[arch-commits] Commit in (4 files)

[Kpcyrd]

    Date: Tuesday, March 3, 2020 @ 22:58:45
  Author: kpcyrd
Revision: 589861

addpkg: torbrowser-launcher 0.3.2-2

Added:
  torbrowser-launcher/
  torbrowser-launcher/repos/
  torbrowser-launcher/trunk/
  torbrowser-launcher/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: torbrowser-launcher/trunk/PKGBUILD
===================================================================
--- torbrowser-launcher/trunk/PKGBUILD	                        (rev 0)
+++ torbrowser-launcher/trunk/PKGBUILD	2020-03-03 22:58:45 UTC (rev 589861)
@@ -0,0 +1,36 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+
+pkgname=torbrowser-launcher
+pkgver=0.3.2
+pkgrel=2
+pkgdesc="Securely and easily download, verify, install, and launch Tor Browser in Linux"
+url="https://github.com/micahflee/torbrowser-launcher"
+depends=('python' 'python-pyqt5' 'python-requests' 'python-pysocks' 'python-gpgme' 'gnupg' 'tor')
+makedepends=('python-setuptools' 'python-distro')
+optdepends=('apparmor: support for apparmor profiles')
+arch=('any')
+license=('MIT')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/micahflee/torbrowser-launcher/archive/v${pkgver}.tar.gz"
+        "https://github.com/micahflee/torbrowser-launcher/pull/444/commits/66781d299d9dfd812c7aca9a04de7ea37f4d57e2.patch")
+sha512sums=('26c5517723c730591ea5c4b81e30728e9db7323afcafc99d17a178d4300bad3df8731ffb063cc53fe189a3b5e2872395c913b9eea6595acac7f31ff4a1c5f105'
+            'af8110da76a2d5763a158c436e712e1929b7524de129b4b3d09d7175df3ba45731a3924480415902cb5b27d1885bbc64c09fb4416367e2aa461e7c0ba3443b3e')
+b2sums=('b3e35f546ef84aec02a3b75068b08a6d60f9f41f6194d1bf25862c48780f77d72e4443e594add04c5a0d44cf01bcfc8c04d6d7d67c767c2cc75cc8b4a9c42f9c'
+        '198da65696d6586f8fe279c8161f18e335ee8677c3a1026fda47933046313955648567d24fdfb01cbf533bab31a6526da0adb8861782079e151705011d9afd94')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  patch --forward --strip=1 --input="${srcdir}/66781d299d9dfd812c7aca9a04de7ea37f4d57e2.patch"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim:set ts=2 sw=2 et: