[arch-commits] Commit in lib32-curl/repos (2 files)

[Christian Hesse]

    Date: Wednesday, March 4, 2020 @ 08:19:20
  Author: eworm
Revision: 589892

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-curl/repos/multilib-testing-x86_64/
  lib32-curl/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 589891, lib32-curl/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: lib32-curl/repos/multilib-testing-x86_64/PKGBUILD (from rev 589891, lib32-curl/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2020-03-04 08:19:20 UTC (rev 589892)
@@ -0,0 +1,58 @@
+# Maintainer: Daniel Wallace <danielwallace at aur.archlinux.org>
+# Contributor: Dave Reisner <dreisner at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Lucien Immink <l.immink at student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=lib32-curl
+_pkgname=curl
+pkgver=7.69.0
+pkgrel=1
+pkgdesc="An URL retrieval utility and library (32-bit)"
+arch=('x86_64')
+url="https://curl.haxx.se"
+license=('MIT')
+depends=('lib32-libssh2' 'lib32-krb5' 'lib32-libpsl' 'lib32-zlib' "${_pkgname}")
+source=("https://curl.haxx.se/download/$_pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('0ecd9e6e55cb19400fafdcd723c72667903ec760652e60fe0b884a672e1ac5d8667c8837422145a9af995ffe36d31a2685296f272ebddf1f5f1a7b12baf0fbad'
+            'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --with-gssapi \
+      --with-libssh2 \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+      --libdir=/usr/lib32
+
+  make
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "${pkgdir}"/usr/{share,bin,include}
+
+  # license
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"
+}