[arch-commits] Commit in hledger-web/repos (2 files)

[Felix Yan]

    Date: Wednesday, March 4, 2020 @ 13:15:25
  Author: felixonmars
Revision: 590118

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger-web/repos/community-staging-x86_64/
  hledger-web/repos/community-staging-x86_64/PKGBUILD
    (from rev 590117, hledger-web/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: hledger-web/repos/community-staging-x86_64/PKGBUILD (from rev 590117, hledger-web/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-04 13:15:25 UTC (rev 590118)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger-web
+pkgver=1.16.2
+pkgrel=36
+pkgdesc="Web interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-aeson' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-clientsession'
+         'haskell-cmdargs' 'haskell-conduit' 'haskell-data-default' 'haskell-decimal'
+         'haskell-hjsmin' 'haskell-http-conduit' 'haskell-http-client' 'haskell-http-types'
+         'haskell-conduit-extra' 'haskell-safe' 'haskell-shakespeare' 'haskell-utf8-string'
+         'haskell-wai' 'haskell-wai-cors' 'haskell-wai-extra' 'haskell-wai-handler-launch'
+         'haskell-warp' 'haskell-yesod' 'haskell-yesod-core' 'haskell-yesod-form'
+         'haskell-yesod-static' 'haskell-megaparsec')
+makedepends=('ghc' 'haskell-hspec' 'haskell-yesod-test')
+replaces=('hledger-api')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('830b11d0b0ef2894eed6c49e161aa3e4b175414e6315a78e37dbc3a0749b25dcf0d855e9144ce8c0ffb721fccf34b7daad0c5f4b808315ad0d143e941268a2dc')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e '/semigroups/d' $pkgname.cabal
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-dev -f-library-only -fthreaded
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}