[arch-commits] Commit in haskell-hakyll/repos (2 files)

[Felix Yan]

    Date: Saturday, March 7, 2020 @ 14:02:02
  Author: felixonmars
Revision: 591153

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hakyll/repos/community-staging-x86_64/
  haskell-hakyll/repos/community-staging-x86_64/PKGBUILD
    (from rev 591152, haskell-hakyll/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: haskell-hakyll/repos/community-staging-x86_64/PKGBUILD (from rev 591152, haskell-hakyll/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-07 14:02:02 UTC (rev 591153)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hakyll
+pkgname=haskell-hakyll
+pkgver=4.13.0.1
+pkgrel=32
+pkgdesc="A static website compiler library"
+url="https://jaspervdj.be/hakyll"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-cryptohash'
+         'haskell-data-default' 'haskell-file-embed' 'haskell-fsnotify' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-lrucache' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'pandoc' 'pandoc-citeproc' 'haskell-random'
+         'haskell-regex-tdfa' 'haskell-resourcet' 'haskell-scientific' 'haskell-tagsoup'
+         'haskell-time-locale-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-wai' 'haskell-wai-app-static' 'haskell-warp' 'haskell-yaml')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('36d3d0c9e3cefbc6b159ec868a523be37cfd92db8997f914cbf9eb568cba6f16169048aca7d4bebdf8a800ec3ed6bb710c9330723b3444629ab8fae77e9325df')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e 's/< *0.17/<1/' -e 's/< *1.3/<2/' -e 's/< *2/<3/' -e 's/< *3.3/<4/' -e 's/< *0.15/<1/' $_hkgname.cabal
+    sed -i 's/fail /error /' lib/Hakyll/Core/Metadata.hs lib/Hakyll/Web/Redirect.hs lib/Hakyll/Web/Template/Context.hs
+    sed -i '/fail = /i instance MonadFail Compiler where' lib/Hakyll/Core/Compiler/Internal.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fcheckexternal -fwatchserver -fpreviewserver -fusepandoc
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "https://github.com/jaspervdj/hakyll/issues/682"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}