[arch-commits] Commit in gnome-desktop/repos (2 files)

[Jan Steffens]

    Date: Saturday, March 7, 2020 @ 23:34:17
  Author: heftig
Revision: 376920

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-desktop/repos/gnome-unstable-x86_64/
  gnome-desktop/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 376919, gnome-desktop/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: gnome-desktop/repos/gnome-unstable-x86_64/PKGBUILD (from rev 376919, gnome-desktop/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-07 23:34:17 UTC (rev 376920)
@@ -0,0 +1,47 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jan at archlinux.org>
+
+pkgname=gnome-desktop
+pkgver=3.35.91+2+g36a8f2e2
+pkgrel=1
+epoch=1
+pkgdesc="Library with common API for various GNOME modules"
+url="https://gitlab.gnome.org/GNOME/gnome-desktop"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gsettings-desktop-schemas gtk3 libxkbfile xkeyboard-config iso-codes libseccomp bubblewrap
+         systemd-libs)
+makedepends=(gobject-introspection git meson gtk-doc yelp-tools)
+checkdepends=(xorg-server-xvfb)
+provides=(libgnome-desktop-3.so)
+_commit=36a8f2e27d54f4114f49c3cc2f176e6f8e9163d8  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gnome_distributor="Arch Linux®" \
+    -D gtk_doc=true \
+    -D date_in_gnome_version=false
+  ninja -C build
+}
+
+check() {
+  # tests broken: missing locale he_IL.UTF-8
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs || :
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}