[arch-commits] Commit in nautilus/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 01:33:25
  Author: heftig
Revision: 376940

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  nautilus/repos/gnome-unstable-x86_64/
  nautilus/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 376939, nautilus/trunk/PKGBUILD)

----------+
 PKGBUILD |   75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

Copied: nautilus/repos/gnome-unstable-x86_64/PKGBUILD (from rev 376939, nautilus/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-08 01:33:25 UTC (rev 376940)
@@ -0,0 +1,75 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=nautilus
+pkgname=(nautilus libnautilus-extension)
+pkgver=3.36.0
+pkgrel=1
+pkgdesc="Default file manager for GNOME"
+url="https://wiki.gnome.org/Apps/Files"
+arch=(x86_64)
+license=(GPL)
+depends=(libgexiv2 gnome-desktop gvfs dconf tracker nautilus-sendto gnome-autoar
+         gst-plugins-base-libs tracker-miners)
+makedepends=(gobject-introspection git gtk-doc meson appstream-glib)
+_commit=e11034204be70a8535c8eff0010a2881991f17eb  # tags/3.36.0^0
+source=("git+https://gitlab.gnome.org/GNOME/nautilus.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd $pkgbase
+
+  git submodule init
+  git submodule set-url subprojects/libgd "$srcdir/libgd"
+  git submodule update
+}
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D docs=true \
+    -D packagekit=false
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_nautilus() {
+  depends+=(libnautilus-extension)
+  groups=(gnome)
+
+  DESTDIR="$pkgdir" meson install -C build
+
+### Split libnautilus-extension
+
+  _pick libne "$pkgdir"/usr/include
+  _pick libne "$pkgdir"/usr/lib/{girepository-1.0,libnautilus-extension*,pkgconfig}
+  _pick libne "$pkgdir"/usr/share/{gir-1.0,gtk-doc}
+}
+
+package_libnautilus-extension() {
+  pkgdesc="Library for extending the $pkgdesc"
+  depends=(gtk3)
+  provides=(libnautilus-extension.so)
+  mv libne/* "$pkgdir"
+}
+
+# vim:set sw=2 et: