[arch-commits] Commit in gnome-settings-daemon/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 03:50:56
  Author: heftig
Revision: 376969

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-settings-daemon/repos/gnome-unstable-x86_64/
  gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 376968, gnome-settings-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD (from rev 376968, gnome-settings-daemon/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-08 03:50:56 UTC (rev 376969)
@@ -0,0 +1,47 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-settings-daemon
+pkgver=3.35.92+5+g6cb14714
+pkgrel=1
+pkgdesc="GNOME Settings Daemon"
+url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse libnotify systemd-libs
+         libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather geocode-glib geoclue nss
+         libgudev gtk3-print-backends libnm gcr)
+makedepends=(xf86-input-wacom libxslt docbook-xsl python git meson)
+checkdepends=(python-gobject python-dbusmock)
+groups=(gnome)
+backup=(etc/xdg/Xwayland-session.d/00-xrdb)
+_commit=6cb1471479f38b3178efd3577a19aec6b62f73fb  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}