[arch-commits] Commit in mutter/repos (3 files)

Jan Steffens heftig at archlinux.org
Sun Mar 8 03:58:39 UTC 2020


    Date: Sunday, March 8, 2020 @ 03:58:39
  Author: heftig
Revision: 376974

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  mutter/repos/gnome-unstable-x86_64/
  mutter/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 376972, mutter/trunk/PKGBUILD)
  mutter/repos/gnome-unstable-x86_64/mutter.install
    (from rev 376972, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   58 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 ++++++
 2 files changed, 65 insertions(+)

Copied: mutter/repos/gnome-unstable-x86_64/PKGBUILD (from rev 376972, mutter/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-08 03:58:39 UTC (rev 376974)
@@ -0,0 +1,58 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=3.36.0
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas libcanberra
+         startup-notification zenity libsm gnome-desktop upower libxkbcommon-x11
+         gnome-settings-daemon libgudev libinput pipewire xorg-server-xwayland)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server sysprof)
+checkdepends=(xorg-server-xvfb)
+provides=(libmutter-6.so)
+groups=(gnome)
+install=mutter.install
+_commit=6b852e6cb30559b2ab56bb29ccc2e8f95aa89f89  # tags/3.36.0^0
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D xwayland_initfd=disabled \
+    -D installed_tests=false
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  # Unexpected passes in conform test
+  # Stacking test flaky
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    meson test -C build --print-errorlogs || :
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/gnome-unstable-x86_64/mutter.install (from rev 376972, mutter/trunk/mutter.install)
===================================================================
--- gnome-unstable-x86_64/mutter.install	                        (rev 0)
+++ gnome-unstable-x86_64/mutter.install	2020-03-08 03:58:39 UTC (rev 376974)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}



More information about the arch-commits mailing list