[arch-commits] Commit in evolution/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 06:19:44
  Author: heftig
Revision: 377013

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evolution/repos/gnome-unstable-x86_64/
  evolution/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 377010, evolution/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: evolution/repos/gnome-unstable-x86_64/PKGBUILD (from rev 377010, evolution/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-08 06:19:44 UTC (rev 377013)
@@ -0,0 +1,72 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=evolution
+pkgname=(evolution evolution-bogofilter evolution-spamassassin)
+pkgver=3.36.0
+pkgrel=1
+pkgdesc="Manage your email, contacts and schedule"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(x86_64)
+license=(GPL)
+depends=(gnome-desktop evolution-data-server libcanberra libpst libytnef
+         dconf gspell libcryptui gnome-autoar)
+makedepends=(intltool itstool docbook-xsl networkmanager bogofilter
+             spamassassin highlight gtk-doc yelp-tools git cmake)
+options=(!emptydirs)
+_commit=5eb0771874ec867a4883bd53abdf05c0fe58439a  # tags/3.36.0^0
+source=("git+https://gitlab.gnome.org/GNOME/evolution.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^EVOLUTION_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  cmake -H$pkgbase -Bbuild \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_SMIME=ON \
+    -DENABLE_GTK_DOC=ON
+  cmake --build build
+}
+
+package_evolution() {
+  depends+=(libcamel-1.2.so libebook-1.2.so libebook-contacts-1.2.so
+            libecal-2.0.so libedataserver-1.2.so libedataserverui-1.2.so)
+  optdepends=('highlight: text highlight plugin'
+              'evolution-spamassassin: Spamassassin spam check plugin'
+              'evolution-bogofilter: Bogofilter spam check plugin')
+  groups=(gnome-extra)
+
+  DESTDIR="$pkgdir" cmake --build build --target install
+
+### Split
+  local x
+  for x in bogofilter spamassassin; do
+    mkdir -p $x/usr/{lib/evolution/modules,share/metainfo}
+    mv {"$pkgdir",$x}/usr/lib/evolution/modules/module-$x.so
+    mv {"$pkgdir",$x}/usr/share/metainfo/org.gnome.Evolution-$x.metainfo.xml
+  done
+}
+
+
+package_evolution-bogofilter() {
+  pkgdesc="Spam filtering for Evolution, using Bogofilter"
+  depends=("evolution=$pkgver" bogofilter)
+
+  mv bogofilter/usr "$pkgdir"
+}
+
+package_evolution-spamassassin() {
+  pkgdesc="Spam filtering for Evolution, using SpamAssassin"
+  depends=("evolution=$pkgver" spamassassin)
+
+  mv spamassassin/usr "$pkgdir"
+}