[arch-commits] Commit in gnome-builder/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 07:06:29
  Author: heftig
Revision: 377055

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-builder/repos/gnome-unstable-x86_64/
  gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 377054, gnome-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD (from rev 377054, gnome-builder/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-03-08 07:06:29 UTC (rev 377055)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-builder
+pkgver=3.36.0
+pkgrel=1
+pkgdesc="An IDE for writing GNOME-based software"
+url="https://wiki.gnome.org/Apps/Builder"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtksourceview4 devhelp libgit2-glib gjs python-gobject clang desktop-file-utils ctags
+         libpeas vte3 vala python-jedi autoconf-archive sysprof flatpak-builder gspell libdazzle
+         template-glib jsonrpc-glib python-sphinx webkit2gtk glade python-lxml meson libportal)
+makedepends=(llvm gobject-introspection gtk-doc yelp-tools appstream-glib git mm-common
+             python-sphinx_rtd_theme)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-code-assistance: Legacy assistance services')
+groups=(gnome-extra)
+_commit=d73cecfb8bf4b40df32d7f81607e5b24a3536bb4  # tags/3.36.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-builder.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D docs=true \
+    -D help=true
+  ninja -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: