[arch-commits] Commit in gnome-applets/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 07:58:27
  Author: heftig
Revision: 591487

archrelease: copy trunk to community-testing-x86_64

Added:
  gnome-applets/repos/community-testing-x86_64/
  gnome-applets/repos/community-testing-x86_64/PKGBUILD
    (from rev 591482, gnome-applets/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: gnome-applets/repos/community-testing-x86_64/PKGBUILD (from rev 591482, gnome-applets/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-03-08 07:58:27 UTC (rev 591487)
@@ -0,0 +1,47 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-applets
+pkgver=3.34.0
+pkgrel=2
+pkgdesc="Small applications for the GNOME Panel"
+arch=('x86_64')
+url="https://wiki.gnome.org/Projects/GnomeApplets"
+license=('GPL')
+depends=('dbus-glib' 'gnome-panel' 'libgtop' 'tracker' 'cpupower' 'upower')
+makedepends=('autoconf-archive' 'git' 'gnome-settings-daemon' 'intltool' 'python' 'yelp-tools')
+_commit=5dffba205cb6137b935547739c1170ccfc03814c  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-applets.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Use correct D-Bus config location
+  sed -i '/^dbus_confdir =/ s/sysconfdir/datadir/' cpufreq/src/cpufreq-selector/Makefile.am
+
+  # Disable buggy applets
+  # https://gitlab.gnome.org/GNOME/gnome-applets/issues/6
+  sed -i '/window-buttons/d
+          /window-title/d' Makefile.am
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
+              --disable-schemas-compile --enable-compile-warnings=minimum
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}