[arch-commits] Commit in gnome-flashback/repos (3 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 08:02:20
  Author: heftig
Revision: 591496

archrelease: copy trunk to community-testing-x86_64

Added:
  gnome-flashback/repos/community-testing-x86_64/
  gnome-flashback/repos/community-testing-x86_64/PKGBUILD
    (from rev 591493, gnome-flashback/trunk/PKGBUILD)
  gnome-flashback/repos/community-testing-x86_64/gettext.diff
    (from rev 591493, gnome-flashback/trunk/gettext.diff)

--------------+
 PKGBUILD     |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 gettext.diff |   12 ++++++++++++
 2 files changed, 67 insertions(+)

Copied: gnome-flashback/repos/community-testing-x86_64/PKGBUILD (from rev 591493, gnome-flashback/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-03-08 08:02:20 UTC (rev 591496)
@@ -0,0 +1,55 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-flashback
+pkgver=3.35.2
+pkgrel=1
+pkgdesc="GNOME Flashback session"
+arch=('x86_64')
+url="https://wiki.gnome.org/Projects/GnomeFlashback"
+license=('GPL')
+depends=('gnome-bluetooth' 'gnome-panel' 'gnome-session' 'gnome-settings-daemon' 'gnome-themes-standard' 'libibus' 'metacity')
+makedepends=('autoconf-archive' 'git' 'intltool' 'python')
+optdepends=('gnome-backgrounds: Default background'
+            'gnome-control-center: System settings'
+            'gnome-screensaver: Lock screen'
+            'network-manager-applet: Network management')
+_commit=594419b3173152c967c855d3be5769d2a2f38b4e  # tags/3.35.2^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-flashback.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
+        gettext.diff)
+sha256sums=('SKIP'
+            'SKIP'
+            'e947f51efca2efcae36755406f1b9a191981fc09a819fe148bc41451a08341d4')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  patch -Np1 -i ../gettext.diff  # Unbreak build with gettext 0.20
+
+  git submodule init
+  git submodule set-url gvc/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
+              --disable-schemas-compile --enable-compile-warnings=minimum --enable-gtk-doc
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}

Copied: gnome-flashback/repos/community-testing-x86_64/gettext.diff (from rev 591493, gnome-flashback/trunk/gettext.diff)
===================================================================
--- community-testing-x86_64/gettext.diff	                        (rev 0)
+++ community-testing-x86_64/gettext.diff	2020-03-08 08:02:20 UTC (rev 591496)
@@ -0,0 +1,12 @@
+diff --git i/configure.ac w/configure.ac
+index 5dbd86d..0e586c1 100644
+--- i/configure.ac
++++ w/configure.ac
+@@ -71,6 +71,7 @@ dnl **************************************************************************
+ 
+ AM_GNU_GETTEXT([external])
+ AM_GNU_GETTEXT_VERSION([0.19.4])
++AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.4])
+ 
+ GETTEXT_PACKAGE=gnome-flashback
+ AC_SUBST([GETTEXT_PACKAGE])