[arch-commits] Commit in weston/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 8, 2020 @ 08:13:44
  Author: heftig
Revision: 591508

archrelease: copy trunk to community-testing-x86_64

Added:
  weston/repos/community-testing-x86_64/
  weston/repos/community-testing-x86_64/PKGBUILD
    (from rev 591507, weston/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: weston/repos/community-testing-x86_64/PKGBUILD (from rev 591507, weston/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-03-08 08:13:44 UTC (rev 591508)
@@ -0,0 +1,49 @@
+# Maintainer: Sébastien Luttringer
+# Contributor: Joel Teichroeb <joel at teichroeb.net>
+
+pkgname=weston
+pkgver=8.0.0
+pkgrel=2
+pkgdesc='Reference implementation of a Wayland compositor'
+arch=('x86_64')
+url='https://wayland.freedesktop.org/'
+license=('MIT')
+depends=('glibc' 'wayland' 'libxkbcommon' 'libinput' 'libunwind' 'pixman'
+         'libdrm' 'pam' 'systemd-libs' 'cairo' 'libpng' 'libjpeg-turbo' 'libwebp'
+         'mesa' 'libegl' 'libgles' 'glib2' 'pango' 'lcms2' 'mtdev' 'libx11'
+         'libxcb' 'dbus' 'libva' 'libxcursor' 'colord' 'libpipewire02')
+makedepends=('wayland-protocols' 'meson' 'ninja' 'freerdp')
+optdepends=('freerdp: support rdp backend')
+validpgpkeys=('34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48' # emersion <contact at emersion.fr>
+              'C7223EBE4EF66513B892598911A30156E0E67611' # Bryce Harrington
+              'C0066D7DB8E9AC6844D728715E54498E697F11D7') # Derek Foreman
+source=("https://wayland.freedesktop.org/releases/$pkgname-$pkgver.tar.xz"{,.sig})
+md5sums=('53e4810d852df0601d01fd986a5b22b3'
+         'SKIP')
+
+prepare() {
+  cd $pkgname-$pkgver
+  # apply patch from the source array (should be a pacman feature)
+  local src
+  for src in "${source[@]}"; do
+    src="${src%%::*}"
+    src="${src##*/}"
+    [[ $src = *.patch ]] || continue
+    msg2 "Applying patch $src..."
+    patch -Np1 < "../$src"
+  done
+}
+
+build() {
+  arch-meson $pkgname-$pkgver build \
+    --libexec=lib/weston -D b_lto=false -D simple-dmabuf-drm=auto
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  # license
+  install -Dm644 $pkgname-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# vim:set ts=2 sw=2 et: